2

The documentation for AccountingForm states:

AccountingForm acts as a "wrapper", which affects printing, but not evaluation.

However,

x = AccountingForm[1500.12, {7, 2}, DigitBlock -> 3];
x/2

1,500.12 / 2

Where 1,500.12 is not resolved to its number and 750.06 is not returned as either a number nor an AccountingForm number. What does the documentation statement mean? It appears that the formatting functions do affect evaluation as no evaluation occurs if a formatted number is used. Bug or am I missing something?

Edmund
  • 42,267
  • 3
  • 51
  • 143
  • This isn't just an AccountingForm[] thing, the line is repeated, for instance, in NumberForm[]. – Feyre Mar 06 '17 at 14:08
  • @Feyre Yes, I am using AccountingForm as an example; hence the "e.g.". – Edmund Mar 06 '17 at 14:34
  • 1
    quite recent: 139366 – Kuba Mar 06 '17 at 15:46
  • 1
    yes its an annoying deficiency in the documentation. Just think how much grief they would save newcomers (and us) with a few words to the effect that the results of "*Form" should not be used for further processing. – george2079 Mar 06 '17 at 15:55
  • @george2079. That is not quite right. As long as you do not assign the Form expression to a symbol, you can further process the result. If by abuse you assigned the Form expression to a symbol, you can use the result by taking part 1. – Fred Simons Mar 06 '17 at 16:34
  • I suppose its worth pointing out here Out ( ie % ) accesses prior "results" without the "wrapper" if the previous expression is wrapped in a "*Form". (also not well documented) – george2079 Mar 06 '17 at 16:45

2 Answers2

1

AccountingForm and similar formatters are typeset with an InterpretationBox:

InterpretationBox[boxes, expr] is a low-level box construct that displays as boxes but is interpreted on input as expr.

The internal "kernel" FullForm is still AccountingForm[1500.12,...], but the box form in the front end is

Cell[BoxData[
 TagBox[
  InterpretationBox["\<\"1,500.12\"\>",
   1500.12,
   AutoDelete->True],
  AccountingForm[#, {7, 2}, DigitBlock -> 3]& ]], "Output",
 CellChangeTimes->{3.697810013552223*^9}]

When the expression is copied in the front end and pasted as input, the InterpretationBox is passed to the kernel and "interpreted," that is, the second argument 1500.12 is used for the value.

The OP's example, with the output copied as input:

One can do the same thing programmatically with

ToExpression@ToBoxes[x/2, StandardForm]
(*  750.06  *)

The upshot is that output-formatters are intended to be used for formatting output, not internally in computations. At least, that seems to be the intention.

Appendix

I just noticed this subtlety:

If the output of the first line is typeset, then in the subsequent %/2, the AccountingForm is interpreted as a number; if the output suppressed with a semicolon, then the internal FullForm is used and AccountingForm[..] is left unchanged.

Michael E2
  • 235,386
  • 17
  • 334
  • 747
0

My guess is that they mean the evaluation of the arguments to AccountingForm.

x = AccountingForm[1500.12, {7, 2}, DigitBlock -> 3]

For sure you can not use x directly in a computation. This is clear if you look at the FullForm.

x/2 // FullForm

Mathematica graphics

Instead attempt to extract the numerical value:

(x /. AccountingForm[z_?NumericQ, y___] -> z)/2

(* 750.06 *)

Fed Simons commented that an easier way is to use Part.

x[[1]]/2

(* 750.06 *)
Jack LaVigne
  • 14,462
  • 2
  • 25
  • 37