PlotStyle Crosses needed

Question

I want the the dots replaced by crosses in the following plot

Plot[Sin[x],{x,0,6.5},PlotStyle ->{Blue,Dotted}]

Could anyone help please?

ListPlot[Table[Sin[x], {x, 0, 6.5, 0.25}], PlotMarkers -> "+" ] — LouisB, Mar 11 '17 at 06:16

score 8 · Answer 1 · edited Jun 16 '20 at 09:23

8

Using MeshFunctions->{"ArcLength"} to get equally spaced mesh points and post-processing Points to "\[Cross]"s:

Plot[Sin[x], {x, -2 Pi, 2 Pi}, PlotStyle -> None, Mesh -> 60,
  MeshFunctions -> {"ArcLength"}, MeshStyle -> Blue] /. 
 Point[x_] :> (Text[Style["\[Cross]", 12], #] & /@ x)

Mathematica graphics

Notes:

As noted by @Mr.Wizard in the comments, to get equal arclengths we need to use AspectRatio->Automatic:

Plot[Sin[x], {x, -2 Pi, 2 Pi}, PlotStyle -> None, Mesh -> 60, 
  AspectRatio -> Automatic, MeshFunctions -> {"ArcLength"}, 
  MeshStyle -> Blue, PlotRangePadding -> .2, ImageSize -> 500] /. 
 Point[x_] :> (Text[Style["\[Cross]", 12], #] & /@ x)

Mathematica graphics

Also, as noted in Point Renderings Slightly Off in Mathematica

Precise positioning is not really achievable when glyphs from a font are used as plot markers

This issue can be dealt with using the third argument of Text, e.g., Text[Style["\[Cross]", 30], #, Scaled[{.5, .46}]] as suggested by @Mr.Wizard in the comments (see also this answer by Mr.W). Alternatively, we can make a graphics version of \[Cross]

cross = First[First[ImportString[ExportString[ Style["\[Cross]", Italic,
    FontSize -> 24, FontFamily -> "Times"], "PDF"], "PDF", "TextMode" -> "Outlines"]]]

and use Inset[Graphics[{Blue, cross}, ImageSize -> 8], #] & instead of Text[Style["\[Cross]", 12], #] & above.

edited Jun 16 '20 at 09:23

Community

1

answered Mar 11 '17 at 07:15

kglr

394,356
18
477
896

Nice! But it's not evenly spaced without AspectRatio -> Automatic. – Mr.Wizard Mar 11 '17 at 07:31
@Mr.Wizard, good point, thank you. – kglr Mar 11 '17 at 07:32
Also why not Mesh -> 100 ? – Mr.Wizard Mar 11 '17 at 07:35
@Mr.Wizard, of course!! Thank you again. – kglr Mar 11 '17 at 07:43
Since we seem to have a good thing going you might want something like Text[Style["\[Cross]", 30], #, Scaled[{.5, .46}]] compensate for glyph offset, re: (75342). – Mr.Wizard Mar 11 '17 at 07:55
1

You can get even spacing with other aspect ratios using ScalingFunctions like I did here. – Michael E2 Mar 11 '17 at 14:20
Thank you @Michael. I am still on Version 9, and could not get ScalingFunctions work in Plot. – kglr Mar 11 '17 at 15:16
In V9, try inserting PlotRange -> 1.02 {{-GoldenRatio, GoldenRatio}, {-1, 1}} with the ScalingFunctions in arclengthmesh[]. The factor 1.02 should probably depend on PlotRangePadding, which is Scaled[0.02] by default. Maybe it's not worth pursuing, since the way ScalingFunctions works has changed. – Michael E2 Mar 11 '17 at 15:40
And it's different in V10 than either V11 or V9.... :( – Michael E2 Mar 11 '17 at 15:50
Running the cross definition gives Import::general: Unknown font type /CIDFontType0. Any ideas what is wrong? – Kvothe Sep 12 '18 at 10:17

PlotStyle Crosses needed

1 Answers1