How to make a custom Echo

Question

I usually check my intermediate variable by Echo.Like

Table[Echo@x, {x, 10}]

But when the intermediate variable have too much value,the Font-End often crash,such as Table[Echo@x, {x, 10^3}].So I want to make a custom myEcho,which always show the first 5 results when I run Table[myEcho@x, {x, 10}] every time.Like

Table[myEcho@x, {x, 10}]

Or we can specify the times that we hope,such as Table[myEcho[x,3], {x, 10}] will show the first 3 results

---

As the Kuba's fix,this is current method.

Clear[fun, myEcho]
fun[n_: 5] := 
 Module[{times = 0}, (times++; If[times <= n, Echo, Identity][#]) &]

myEcho = fun[5];
Table[myEcho@x, {x, 10}]

But the weakness is obvious still,which mean I should run myEcho = fun[5];Table[myEcho@x, {x, 10}] every time.Actually I hope get a same result when I just run Table[myEcho@x, {x, 10}].

Answer 1

Here is how I would approach this:

Clear[myEcho, myEchoCounter]
myEcho::stop = "Further output from `` will be suppressed during evaluation of In[``].";
myEcho[, ] := myEcho[];
myEcho[label_: Null, max_: 3][expr_] /; myEchoCounter[$Line, label] >= max := expr
myEcho[label_: Null, max_: 3][expr_] := (
   If[Not@NumberQ[myEchoCounter[$Line, label]], myEchoCounter[$Line, label] = 0];
   If[myEchoCounter[$Line, label] < max, 
    If[MatchQ[label, Null | None], Echo[expr], Echo[expr, label]]];
   If[++myEchoCounter[$Line, label] == max, 
    Message[myEcho::stop, "myEcho"[label, max], $Line]];
   expr);

Now

(myEcho["Before Table"][x]; Table[myEcho["Table"][x], {x, 10}]; myEcho["After Table"][x])

(Table[myEcho[, 3][x], {x, 10}]; Table[myEcho[, 6][x], {x, 10}])

Answer 2

Another way to do this:

In[1]:= << GeneralUtilities`

In[2]:= $MaximumEchoRate = 5;

In[3]:= Table[EchoHold@x, {x, 10}]

x \[Function] 1

x \[Function] 2

x \[Function] 3

x \[Function] 4

x \[Function] 5

During evaluation of In[3]:= Maximum echo rate exceeded, change $MaximumEchoRate to adjust.

Out[3]= {1, 2, 3, 4, 5, 6, 7, 8, 9, 10}

Answer 3

---

Update

I figured that I can make the code much faster (close to the speed without any Echo) if I can get rid of all the if's and let the pattern matcher(which is pretty fast) do all the heavy work for me.

BeginPackage["MyEcho`"];
MaxEchoCount=5;
MyEcho::stop="Max Echo count of reached, further will be suppressed during evaluation of In[``].";
SetAttributes[MyEcho,HoldAllComplete]
Module[{list={}},
MyEcho[label_,return_,subexpr___]:=
Which[
list[[label]]<MyEchoMaxEchoCount,list[[label]]++;Echo[return,subexpr], list[[label]]==MyEchoMaxEchoCount,Message[MyEcho::stop,MyEcho`MaxEchoCount,Defer[Echo[return,subexpr]],$Line];MyEcho[label,return1_,subexpr1___]:=return1;return];
$Pre=Function[{expr},
Quiet@Cases[DownValues[MyEcho],HoldPattern[MyEcho[label_Integer,e___]]:>Unset[MyEcho[label,e]],Infinity];
list=ConstantArray[0,Length@list];
ReleaseHold[Hold[expr]/. HoldPattern[Echo[subexpr__]]:>With[{c=(AppendTo[list,0];Length@list)},MyEcho[c,subexpr]/;True]],HoldAll];
];
EndPackage[];

The key here is that I will add a narrower definition to MyEcho once it reached the maximum echo count, so the next time it meets the same function at the same place, it will hit the new function definition and directly return.

One can compare this version to the old version, as well as the version with QuietEcho wrapped around the whole expression with the following code:

Table[Flatten[{{Table[Echo[x], 2], Echo[10 - x]}, {Sqrt[2]}}], {x, 1000000}]

The results are:

• Without Echo: 1.84s
• With QuietEcho wrapped around everything: 2.76s
• With the new definition: 2.42s
• With the old definition: 5.61s

---

Old version

crit = 2;
SetAttributes[MyEcho, HoldAll]
Module[{res},MyEcho[label_, return_, subexpr___] :=
  If[NumberQ[label],If[label >= crit, return,
    label++; res = Echo[return, subexpr];
    If[label == crit, Print["Already " <> ToString[crit] <> " Echo here!\nNo more Echo allowed!!!!"]];res],
  label = 1; Echo[return, subexpr]]]
$Pre = 
   Function[{expr}, ReleaseHold[Hold[expr] /. HoldPattern[Echo[subexpr__]] :> 
       With[{u = Unique[]}, MyEcho[u, subexpr] /; True]], HoldAll]

Similar results, but a bit more integrated and more carefully protected.

Note that one can still save the old $Pre by adding it in front of this code.(one must limit the functionality of old $Pre to an extent that full evaluation of expressions is forbidden)

Answer 4

I think this is probably slower than Kuba's solution in comments, but does

myEcho[x_,n_:5]:=If[x<=n,Echo[x],Identity[x]];

Table[myEcho@x,{x,10}]

not achieve what you're looking for?