How to designate arguments in a nested Maps to get specified result?

Question

Say I have two lists,

list1 = {{a, b}, {c, d}}
list2 = {{x, y, z},{x1, y1, z1}}

and I want to map a function f over them to produce

{{f[x, {a, b}], f[y, {a,b}], f[z, {a,b}]},{f[x1, {c, d}], f[y1, {c, d}], f[z1, {c, d}]}

I tried some Mappings, but it seems really complex thing.
Is it possible to generate? Thank you.

score 2 · Answer 1 · answered May 02 '17 at 14:47

2

Modified answer from a closely related topic:

MapThread[Function[{u, b}, f[#, b] & /@ u], {list2, list1}]

{
 {f[x, {a, b}], f[y, {a, b}], f[z, {a, b}]}, 
 {f[x1, {c, d}], f[y1, {c, d}], f[z1, {c, d}]}
}

answered May 02 '17 at 14:47

Kuba

score 1 · Answer 2 · answered May 02 '17 at 14:50

1

This is on of those cases where an ordinary Table loop is by far the easiest solution:

Table[f[#,list1[[i]]]&/@list2[[i]],{i,2}]

Alternatively, you can use MapIndexed

MapIndexed[
 f[#1,list1[[#2[[1]]]]]&,
 list2,
 {2}
]

answered May 02 '17 at 14:50

TimRias

It's all about the speed, as my real lists are really big. Thank you. – Davit Shahnazaryan May 02 '17 at 14:54

Chris Degnen · Answer 3 · 2017-05-02T15:12:19.027

1

Map[Function[arg, f[arg, #1}]], #2] & @@@ Transpose[{list1, list2}]

or, more similar to Kuba's answer

MapThread[Map[Function[arg, f[arg, #1]], #2] &, {list1, list2}]

both yielding

{{f[x, {a, b}], f[y, {a, b}], f[z, {a, b}]},
 {f[x1, {c, d}], f[y1, {c, d}], f[z1, {c, d}]}}

edited May 02 '17 at 15:12

answered May 02 '17 at 15:04

Chris Degnen

score 0 · Answer 4 · answered May 02 '17 at 14:52

0

Ok, it's solved with Distribute.

Distribute[f[{#1}, #2], 
   List] & @@@ {{list2[[1]], list1[[1]]}, {list2[[2]], list1[[2]]}}

answered May 02 '17 at 14:52

4 Answers4