Color the labels given by Label in Plot consistently with the colour of the corresponding function

Question

Consider the following toy example:

With[{
  data = Table[
    Labeled[Sin[n x], n],
    {n, 1, 5}
    ]
  },
 Plot[
  data,
  {x, 0, Pi},
  PlotRange -> All
  ]
 ]

which produces the following plot:

In cases like this, it may be hard to figure out what label corresponds to what plot. Is there an easy way to have the labels coloured consistently with the colour of the corresponding line? This would mean in this example to have the 1 coloured blue, the 2 coloured orange, etc.

Answer 1

You can set the color of the label using Style and assign the color of the curves to be the same as the color of the labels. Further you can control the font face, boldness and size, etc...

First define a list of colors

colors = {Black, Orange, Red, Purple , Blue}

Use colors and Style to assign the color of the text (text arbitrarily set to Bold and font size 14 as an example).

With[
 {
    data = Table[Labeled[Sin[n x],
                 Style[n, Bold, 14, colors[[n]]]], {n, 1, 5}]
  },
 Plot[data, {x, 0, Pi}, PlotRange -> All, PlotStyle -> colors]
 ]

Update

In order to use the default colors (described here) replace colors with ColorData[97, "ColorList"]

With[
 {
  data = Table[Labeled[Sin[n x],

     Style[n, Bold, 14, ColorData[97, "ColorList"][[n]]]],
    {n, 1, 5}]
  },
 Plot[data, {x, 0, Pi}, PlotRange -> All,
  PlotStyle -> ColorData[97, "ColorList"]]
 ]