1

I'm new to Mathematica. I have a Plot that I would like to divide evenly at the y-axis. I can divide evenly at x-axis if I set the min and max range of x.

But, how do I do that at the y-axis, and how do I show the midpoint (x,y values) of each graph?

I would like to show part of the graph when for eg: Plot situation at y-axis from 0-0.2 / 0.2-0.4 / 0.4-0.6 and so forth...but without changing the plotrange that have been set

Here is the code

k = 155900;
F3 = Plot[
  Sqrt[2] √(√(1/m1^2 + 
         20 Sqrt[3118] (1/m1)^(3/2) Sqrt[1/50] + 
         3118020 Sqrt[3118] Sqrt[1/m1] (1/50)^(3/2) + 
         24304810001/50^2 + 623602/(m1 50)) - 
      10 Sqrt[3118] Sqrt[1/m1] Sqrt[1/50] - k/50)
  , {m1, 5, 500}
  , PlotRange -> {{0, 500}, {0, 1}}
  , AxesLabel -> {m1, SuperStar[E]}
  ]

The graph

Zen 禅
  • 23
  • 6
  • 1
    "divide evenly at y-axis" - this is unclear; please clarify what you actually want to achieve. – corey979 May 31 '17 at 14:57
  • I would like to show part of the graph when for eg: graph situation at y-axis from 0-0.2/ 0.2-0.4/ 0.4-0.6/ and so forth. Sorry for my english. I tried to clarify as best as I can. – Zen 禅 May 31 '17 at 15:15
  • k is undefined. – corey979 May 31 '17 at 15:25
  • lets say k value is 155900 – Zen 禅 May 31 '17 at 15:42
  • Maybe you can change the ticks distribution of the y-axis using the package CustomTicks https://scidraw.nd.edu/levelscheme/CustomTicksGuide.pdf – robson denke May 31 '17 at 15:42
  • So you want to make 6 plots, first for y in 0-0.2, second for y in 0.2-0.4 etc.? – corey979 May 31 '17 at 15:44
  • Yes. but without changing the plot range. – Zen 禅 May 31 '17 at 16:02
  • I'm can't understand what is been asked here. @AhmadRuzaini禅, do you have any examples of plots or graphs that are similar to what you need? Can you please [edit] your question to include an example of the expected output? And clarify the text in the question whenever possible. – rhermans May 31 '17 at 16:05
  • By the way, welcome to Mma.SE! To make the most of the site start by taking the [tour] now. It will help us to help you if you write an excellent question. Edit if improvable. As you receive give back, vote and answer questions, keep the site useful, be kind, correct mistakes and share what you have learned. (Notice the links in the comment) – rhermans May 31 '17 at 16:08
  • Related: (6877), (8241) – Mr.Wizard May 31 '17 at 20:38

3 Answers3

1

Perhaps this will work for you.

With[{k = 155900},
  Column[
    Table[
      Plot[
        Sqrt[2] 
          Sqrt[
            Sqrt[1/m1^2 + 20 Sqrt[3118] (1/m1)^(3/2) Sqrt[1/50] + 
              3118020 Sqrt[3118] Sqrt[1/m1] (1/50)^(3/2) + 
              24304810001/50^2 + 623602/(m1 50)] - 
            10 Sqrt[3118] Sqrt[1/m1] Sqrt[1/50] - k/50], 
        {m1, 5, 500},
        PlotRange -> {All, interval},
        AxesLabel -> {m1, SuperStar[E]}],
      {interval, Partition[Range[0., .6, .2], 2, 1]}]]]

plots

m_goldberg
  • 107,779
  • 16
  • 103
  • 257
0
k = 155900;
GraphicsColumn@Table[
  Show[Plot[
    Sqrt[2] \[Sqrt](\[Sqrt](1/m1^2 + 
           20 Sqrt[3118] (1/m1)^(3/2) Sqrt[1/50] + 
           3118020 Sqrt[3118] Sqrt[1/m1] (1/50)^(3/2) + 
           24304810001/50^2 + 623602/(m1 50)) - 
        10 Sqrt[3118] Sqrt[1/m1] Sqrt[1/50] - k/50), {m1, 5, 500}, 
    PlotRange -> {{0, 500}, r}, AxesLabel -> {"m1", SuperStar[E]}],
   PlotRange -> {{0, 500}, {0, 1}}, 
   AxesOrigin -> {0, 0}], {r, {{.4, .8}, {.2, .4}, {0, .2}}}]

enter image description here

george2079
  • 38,913
  • 1
  • 43
  • 110
0
expr = Sqrt[2] √(√(1/m1^2 + 20 Sqrt[3118] (1/m1)^(3/2) Sqrt[1/50] + 
     3118020 Sqrt[3118] Sqrt[1/m1] (1/50)^(3/2) + 24304810001/50^2 + 623602/(m1 50)) - 
     10 Sqrt[3118] Sqrt[1/m1] Sqrt[1/50] - k/50);

Using ConditionalExpression:

Row[Plot[ConditionalExpression[expr, # <= expr <= #2], {m1, 5, 500}, 
    PlotRange -> {{0, 500}, {0, 1}}, AxesLabel -> {m1, SuperStar[E]}, 
    ImageSize -> 300] & @@@ {{0.4, 0.8}, {0.2, 0.4}, {0., 0.2}}]

Mathematica graphics

Using MeshFunctions and MeshShading:

Row[Plot[expr, {m1, 5, 500}, MeshFunctions -> {#2 &}, 
    MeshShading -> {None, Blue}, Mesh -> {#},   MeshStyle -> Opacity[0],
    PlotRange -> {{0, 500}, {0, 1}}, AxesLabel -> {m1, SuperStar[E]}, 
    ImageSize -> 300] & /@ {{0.4, 0.8}, {0.2, 0.4}, {0., 0.2}}]

Mathematica graphics

kglr
  • 394,356
  • 18
  • 477
  • 896
  • Thank you for the answer. How do I show the midpoint for each of the graph? For eg: for graph 0.6-0.4, it will display the midpoint of x and y coordinates of it in the graph. – Zen 禅 Jun 07 '17 at 17:43