DeleteCases based on string length

Question

I have the following dataset

data = {{"one", "two", "three", "a", "b", "c"}, {"four", "five", "d"}}

I want to delete all the strings with length < 2. The desired output is:

{{"one", "two", "three"}, {"four", "five"}}

I found several solutions on this site like:

DeleteCases[#, x_ /; Length[x] < 2] & /@ data

But none of them resulted in my desired output. Any suggestion?

Cases[#, x_ /; StringLength[x] >= 2] & /@ data – garej Jun 01 '17 at 05:32 — garej, Jun 01 '17 at 05:32
Tangentially related: (8945). – Alexey Popkov Jun 01 '17 at 18:23 — Alexey Popkov, Jun 01 '17 at 18:23

score 9 · Accepted Answer · edited May 31 '17 at 20:35

9

many ways to do that..

DeleteCases[#, s_String /; StringLength[s] < 2] & /@ data
DeleteCases[data, s_String /; StringLength[s] < 2, {2}]
Select[#, StringLength[#] > 1 &] & /@ data
data /. s_String /; StringLength[s] < 2 :> Sequence @@ {}

edited May 31 '17 at 20:35

Mr.Wizard

271,378
34
587
1,371

answered May 31 '17 at 18:54

george2079

38,913
1
43
110

OP asked for <2 or if you use select >=2. Please correct your answer – ZaMoC May 31 '17 at 20:33
@Jenny_mathy length must be an integer so >1 and >=2 are equivalent. – george2079 May 31 '17 at 20:40
1

yes of course. any of those two. >2 was wrong – ZaMoC May 31 '17 at 20:43
@Jenny_mathy oh i see, someone fixed it already for me.. – george2079 May 31 '17 at 20:49
4

RuleDelayed has the SequenceHold attribute, so your last version could have been just data /. s_String /; StringLength[s] < 2 -> Sequence[]. In M10.2+ you could also use Nothing instead of Sequence[]. – Carl Woll Jun 01 '17 at 00:57
4

Also, you could use a level spec of {-1} instead of {2} in your second DeleteCases example, in case the input is more deeply nested. – Carl Woll Jun 01 '17 at 00:58

score 3 · Answer 2 · answered May 31 '17 at 18:41

3

Table[Select[data[[i]], StringLength@# >= 2 &], {i, Length@data}]

answered May 31 '17 at 18:41

ZaMoC

6,697
11
31

kglr · Answer 3 · 2017-06-01T11:08:26.913

3

Pick[#, UnitStep[StringLength@# - #2], 1] &[data, 2] (*thanks: @AlexeyPopkov*)

{{"one", "two", "three"}, {"four", "five"}}

edited Jun 01 '17 at 11:08

answered Jun 01 '17 at 00:34

kglr

394,356
18
477
896

3

Note that StringLength is Listable, so your solution can be simplified to Pick[#, UnitStep[StringLength@# - #2], 1] &[data, 2]. – Alexey Popkov Jun 01 '17 at 04:31
Great point, thank you @Alexey. – kglr Jun 01 '17 at 11:10

webcpu · Answer 4 · 2017-06-01T18:13:28.957

1

data = {{"one", "two", "three", "a", "b", "c"}, {"four", "five", "d"}}
data // Map[StringLength@# >= 2 &, #, {-1}] & // Pick[data, #] & (*{2}->{-1}*)

edited Jun 01 '17 at 18:13

answered Jun 01 '17 at 17:01

webcpu

3,182
12
17

1

With third argument of Map being {-1} instead of {2} your solution generalizes to arbitrary deeply nested lists of strings. – Alexey Popkov Jun 01 '17 at 17:54

Ali Hashmi · Answer 5 · 2017-06-01T17:54:07.287

0

Map[Cases[__?(StringLength[#] >= 2 &)]][data]
Map[Cases[x__/;StringLength[x] >= 2]][data]

edited Jun 01 '17 at 17:54

answered Jun 01 '17 at 12:00

Ali Hashmi

8,950
4
22
42

The OP asked for removing <2, so you should use >=2. – Alexey Popkov Jun 01 '17 at 17:49
@AlexeyPopkov thanks. forgot to double check it – Ali Hashmi Jun 01 '17 at 17:53

DeleteCases based on string length

5 Answers5