Colouring in a FilledCurve, self-intersections and all

Question

I have a (vaguely) complex curve with some self-intersections, and I would like to add a filling to the interior. However, the recommended method (of turning Lines into FilledCurves), i.e. by doing something like

ParametricPlot[
  {Cos[t] + 2 Cos[2 t], Sin[t] - 2 Sin[2 t]}
  , {t, 0, 2 π}
  , Frame -> True
  ] /. {Line[pts_] :> {FilledCurve[{Line[pts]}]}}

is unsatisfactory, since, as the documentation puts it,

Filled curves can be non-convex and intersect themselves. Self-intersecting curves are filled according to an even-odd rule that alternates between filling and not at each crossing.

This puts a big hole in the middle of my figure that I would also like to fill:

Mathematica graphics

How can I control the filling in that hole?

ParametricPlot[ r {Cos[t] + 2 Cos[2 t], Sin[t] - 2 Sin[2 t]}, {t, 0, 2 Pi}, {r, 0, 1}, Frame -> True] — Bob Hanlon, Jun 05 '17 at 00:43
@Bob That's nowhere near sufficient - try e.g. changing the weight between the two components. — Emilio Pisanty, Jun 05 '17 at 00:49
That Mathematica does not have an option to disable this behavior is a pretty significant limitation compared to, say, SVG. — , Jun 05 '17 at 01:22

kglr · Answer 1 · 2017-06-05T23:40:22.420

4

pp = ParametricPlot[{Cos[t] + 2 Cos[2 t], Sin[t] - 2 Sin[2 t]}, {t, 0, 2 π} , 
        Frame -> True ] /. {Line[pts_] :> {FilledCurve[Line@pts]}};

bdg = BoundaryDiscretizeGraphics[pp[[1]], Frame->True]

Mathematica graphics

 BoundaryDiscretizeGraphics[pp[[1]], Frame->True, 
   MeshCellStyle -> {{1, All} -> Directive[Thick, Blue], {2} -> Yellow}]

Mathematica graphics

Or, use bdg in RegionPlot (thanks: @Mr.Wizard):

 RegionPlot @ bdg

Mathematica graphics

Note: In version 11, bdg = BoundaryDiscretizeGraphics @@ pp also works.

edited Jun 05 '17 at 23:40

answered Jun 04 '17 at 22:43

kglr

394,356
18
477
896

In v10.1 I need bdg = BoundaryDiscretizeGraphics @@ pp[[1]]; -- if that doesn't break code in other versions you might make that change. – Mr.Wizard Jun 05 '17 at 00:48
That's some pretty interesting tooling. – Emilio Pisanty Jun 05 '17 at 00:49
@Mr.Wizard, i made the change, – kglr Jun 05 '17 at 00:54
Thanks. Depending on the OP's needs RegionPlot[bdg] may be sufficient and significantly cleaner. – Mr.Wizard Jun 05 '17 at 01:00
@Mr.Wizard, thank you again. Added the RegionPlot alternative. – kglr Jun 05 '17 at 01:05

cvgmt · Answer 2 · 2024-02-25T09:21:47.017

4

Now we can use WindingPolygon since v12.

plot = ParametricPlot[{Cos[t] + 2 Cos[2 t], Sin[t] - 2 Sin[2 t]}, {t, 
    0, 2 π}, Frame -> True];
plot /. Line[pts_] :> 
   WindingPolygon[pts, "NonzeroRule"] // BoundaryDiscretizeGraphics

Or

Clear["Global`*"];
Needs["NDSolve`FEM`"]
plot = ParametricPlot[{Cos[t] + 2  Cos[2  t], 
   Sin[t] - 2  Sin[2  t]}, {t, 0, 2  π}, Frame -> True];
m = 
 ToElementMesh@
  DiscretizeGraphics[plot]@"MakeRepresentation"@"ElementMesh"
m // MeshRegion // BoundaryMesh

edited Feb 25 '24 at 09:21

answered Jan 02 '23 at 02:36

cvgmt

72,231
4
75
133

plot = ParametricPlot[{Cos[t] + 2 Cos[2 t], Sin[t] - 2 Sin[2 t]}, {t, 0, 2 π}, Frame -> True]; NDSolve\FEM`ToElementMesh[ DiscretizeGraphics[plot]["MakeRepresentation"["ElementMesh"]]] // MeshRegion // BoundaryMesh` – cvgmt Jul 07 '23 at 12:39

webcpu · Answer 3 · 2017-06-04T20:38:53.897

0

In:

xss = Table[{Cos[t] + 2 Cos[2 t] + 2, Sin[t] - 2 Sin[2 t]}, {t, 0, 
    2 \[Pi], 1/100}];
regionPlot[xss_] := ListLinePlot[
  xss, 
  Filling -> {Axis}, 
  FillingStyle -> LightBlue, 
  AspectRatio -> 1,
   Frame -> True, 
  Axes -> False,
   PlotStyle -> Transparent]
regionPlot@xss

Out:

Mathematica graphics

edited Jun 04 '17 at 20:38

answered Jun 04 '17 at 20:00

webcpu

3,182
12
17

Some notes: my region need not be centered at the origin, and I would like to explicitly avoid double-filling. – Emilio Pisanty Jun 04 '17 at 20:09

Colouring in a FilledCurve, self-intersections and all

3 Answers3