How to get a description of the positions of similar elements in a list?

Question

I want to find a function F to represent the positions of identical elements in a list, which means, for example:

F[{5,6,5,7}]={{1,3},{2},{4}}
F[{5,6,6,5}]={{1,4},{2,3}}
F[{5,7,5,5}]={{1,3,4},{2}}
F[{5,6,7,8}]={{1},{2},{3},{4}}
F[{5,5,5,5}]={{1,2,3,4}}

etc. Is there any function or implementation?

Moreover, I want to use this into an $\underbrace{n\times n\times\cdots\times n}_m$ Table t[n_,m_] (so the dimension $m$ is also an input of t), such that

t[[i_1,...,i_m]]=Subscript[x,F[{i_1,...,i_m}]]

where $1\le i_1,\cdots,i_m\le n$. How can I implement it?

Thanks :)

What is a "partition situation of a list"? Your example is unclear. Give an explanation as well as examples. — David G. Stork, Jun 22 '17 at 00:12
Ohhh.... position situation (not partition situation)! Got it! — David G. Stork, Jun 22 '17 at 00:32
Thanks for your edit! Indeed I don't know how to describe it accurately. — Zigzag1263, Jun 22 '17 at 19:58
The first part of this question is a duplicate of How to efficiently find positions of duplicates? — kglr, Jul 23 '17 at 14:28

score 13 · Accepted Answer · answered Jun 22 '17 at 00:25

13

To get the positions of the same elements in a list you can use PositionIndex

f[x_] := Values@PositionIndex[x]

Test:

f[{5,6,5,7}]
f[{5,6,6,5}]

{{1,3},{2},{4}}

{{1,4},{2,3}}

answered Jun 22 '17 at 00:25

Anjan Kumar

4,979
1
15
28

To make it more simple, try f=Values@*PositionIndex – Wjx Jun 22 '17 at 00:29
@Wjx Thanks for the suggestion. – Anjan Kumar Jun 22 '17 at 00:44

score 2 · Answer 2 · answered Jun 22 '17 at 00:23

One possibility:

F[list_]:=Values @ GroupBy[
    AssociationThread[Range@Length@list, list],
    Identity,
    Keys
]

Your examples:

F[{5,6,5,7}]
F[{5,6,6,5}]
F[{5,7,5,5}]
F[{5,6,7,8}]
F[{5,5,5,5}]

{{1, 3}, {2}, {4}}

{{1, 4}, {2, 3}}

{{1, 3, 4}, {2}}

{{1}, {2}, {3}, {4}}

{{1, 2, 3, 4}}

kglr · Answer 3 · 2017-07-23T17:48:20.070

2

ClearAll[f]
f[lst_] := GatherBy[Range @ Length @ lst, lst[[#]]&]
(* or  f[lst_] := Values @ GroupBy[Range @ Length @ lst, lst[[#]]&] *)

mat = {{5, 6, 5, 7}, {5, 6, 6, 5}, {5, 7, 5, 5}, {5, 6, 7, 8}, {5, 5, 5, 5}};
Grid[Prepend[{#, f@#} & /@ mat, {"list", "f[list]"}], Dividers -> All]

Subscript[x, f@#] & /@ mat

edited Jul 23 '17 at 17:48

answered Jul 23 '17 at 14:14

kglr

394,356
18
477
896

score 2 · Answer 4 · answered Sep 11 '23 at 11:09

2

Values @ Merge[Flatten] @ MapIndexed[Rule[##] &] @ {5, 7, 5, 5}

{{1, 3, 4}, {2}}

answered Sep 11 '23 at 11:09

eldo

67,911
5
60
168

score 1 · Answer 5 · answered Sep 11 '23 at 11:25

1

f[k_List] := 
 Flatten[#, 1] &@Position[k, #] & /@ (k // DeleteDuplicates)

mat = {{5, 6, 5, 7}, {5, 6, 6, 5}, {5, 7, 5, 5}, {5, 6, 7, 8}, {5, 5, 
    5, 5}}; (* borrowed *)

{#, f@#} & /@ mat // Grid[#, Alignment -> Left] &

answered Sep 11 '23 at 11:25

Syed

52,495
4
30
85

How to get a description of the positions of similar elements in a list?

5 Answers5