Counting numbers in a range in a vector

Question

I want to count the number of numbers lying between 0 and -1 in a vector called spec.

I have tried Count[spec,spec<0 && spec>-1], but this does not work. There must be an easy answer...

Old duplicate on Stack Overflow: (6026827). Related: (9637) – Mr.Wizard Jul 01 '17 at 14:13 — Mr.Wizard, Jul 01 '17 at 14:13

kglr · Answer 1 · 2017-12-10T21:45:03.107

10

SeedRandom[1]
spec = RandomReal[{-2, 2}, 100];

Tr[(1 - UnitStep[spec]) UnitStep[spec -(-1)]]
Tr@Unitize@Clip[spec, {-1, 0}, {0, 0}]
Count[spec, _?(-1 <= # <= 0 &)]

all give

24

Some timings:

SeedRandom[1]
s = RandomReal[{-2, 2}, 10^6]; 
Grid[{#, ClearSystemCache[]; AbsoluteTiming[#[s]]} & /@ {
  Length@ Pick[#, Sign@Clip[#, {-1, 0}, {1, 1}], -1] &,
  Tr[(1 - UnitStep[#]) UnitStep[# - (-1)]] &,
  Tr@Unitize@Clip[#, {-1, 0}, {0, 0}] &,
  Count[#, _?(-1 <= # <= 0 &)] &,
  Total[Boole[-1 <= # <= 0] & /@ #] &,
  Length@Select[#, And[# > -1, # < 0] &] &,
  Length@Cases[#, x_ /; -1 < x < 0] &} ]

For SeedRandom[1];s = RandomReal[{-2, 2}, 10^7]; we get:

Note: Still on version 9, so cannot include CountsBy in the timings table.

edited Dec 10 '17 at 21:45

answered Jun 24 '17 at 10:03

kglr

394,356
18
477
896

Great, but why is the condition syntax different from Select []? – Morgan Jun 24 '17 at 12:00
@Morgan, The second argument of Count is a pattern (see Count), while the second argument of Select is a boolean function (see Select) – kglr Jun 24 '17 at 12:12
1

@Morgan see (18054), (88220) – Mr.Wizard Jul 01 '17 at 14:49

ubpdqn · Answer 2 · 2017-06-24T11:34:57.007

4

Total[Boole[-1 <= # <= 0] & /@ spec]

edited Jun 24 '17 at 11:34

answered Jun 24 '17 at 10:25

ubpdqn

60,617
3
59
148

Isn't Unitize redundant? – Coolwater Jun 24 '17 at 11:33
@Coolwater d'oh...I have amended. I had an answer that used Unitize and didn't think. Thanks :) – ubpdqn Jun 24 '17 at 11:36

eldo · Answer 3 · 2017-07-01T13:24:42.127

3

SeedRandom[1]
spec = RandomReal[{-2, 2}, 100];

CountsBy[spec, -1 <= # <= 0 &]

CountsBy[spec, -1 <= # <= 0 &][True]

24

Update

This one is very fast:

s = RandomReal[{-2, 2}, 10^6];

Length @ Pick[s, Sign @ Clip[s, {-1, 0}, {1, 1}], -1] // AbsoluteTiming

{0.032002, 249536}

edited Jul 01 '17 at 13:24

answered Jun 24 '17 at 12:14

eldo

67,911
5
60
168

score 1 · Answer 4 · answered Jun 24 '17 at 09:59

1

Select[spec, And[# > -1, # < 0] &] // Length

answered Jun 24 '17 at 09:59

Morgan

525
2
10

1

For what it's worth, if you change it to Select[spec, -1 < # < 0 &] // Length it gets considerably faster on large lists. – aardvark2012 Jun 24 '17 at 10:27
Nice, thank you. – Morgan Jun 24 '17 at 10:28

score 1 · Answer 5 · answered Jun 24 '17 at 10:33

1

SeedRandom[1];
spec = RandomReal[{-2, 2}, 100000];

Length@Cases[spec, x_ /; -1 < x < 0]

25288

answered Jun 24 '17 at 10:33

aardvark2012

5,424
1
11
22

Counting numbers in a range in a vector

5 Answers5