Creating unique keys from list

Question

I have the following (example) list:

list = {"b", "a", "b", "b", "a", "c", "c", "c", "d", "b", "aa"};

and want to distinguish its elements by appending a counter in the following manner:

ord = Ordering @ Ordering @ list;

Part[#, ord]& @ Flatten[#, 1]& @ 
   MapIndexed[{#1, Last @ #2}&, #, {2}] & @ Gather @ Sort @ list

{{"b", 1}, {"a", 1}, {"b", 2}, {"b", 3}, {"a", 2}, {"c", 1}, {"c", 2}, {"c", 3}, {"d", 1}, {"b", 4}, {"aa", 1}}

This solution is somehow "expensive" (three ordering / sorting) operations, so the question is:

Are there more efficient alternatives?

score 11 · Answer 1 · answered Jun 27 '17 at 20:58

11

Clear[f]
f[_] = 0;
(f[#] = f[#] + 1; {f[#], #}) & /@ list

{{1, "b"}, {1, "a"}, {2, "b"}, {3, "b"}, {2, "a"}, {1, "c"}, {2, "c"}, {3, "c"}, {1, "d"}, {4, "b"}, {1, "aa"}}

answered Jun 27 '17 at 20:58

C. E.

4

Can be shortened to f[_] = 0; {++f[#], #} & /@ list – eldo Jun 27 '17 at 21:37
2

Even better is Clear[f]; f[_] = 0; {#, ++f[#]} & /@ list – m_goldberg Jun 27 '17 at 21:55

score 7 · Accepted Answer · answered Jun 27 '17 at 21:02

7

list = {"b", "a", "b", "b", "a", "c", "c", "c", "d", "b", "aa"}
c = Association[# -> 0 & /@ Union@list]
{#, c[#] += 1} & /@ list

{{"b", 1}, {"a", 1}, {"b", 2}, {"b", 3}, {"a", 2}, {"c", 1}, {"c", 2}, {"c", 3}, {"d", 1}, {"b", 4}, {"aa", 1}}

answered Jun 27 '17 at 21:02

george2079

swish · Answer 3 · 2017-06-27T23:00:36.700

5

Functional style:

FoldPairList[With[{c = Lookup[#1, #2, 1]}, 
   {{#2, c}, Append[#1, #2 -> c + 1]}] &, <||>, list]

edited Jun 27 '17 at 23:00

answered Jun 27 '17 at 22:08

swish

3 Answers3