How do I make a big update(ⓤ) button inside Manipulate?

Question

I often make CDF documents using Manipulate.

However, the Update(ⓤ) button created with ContinousAction-> None is too small.

Is there a way to make this button(ⓤ) bigger?

btw, can you add a simple example where this button works? I could not find it. ps. you code does not match the output, AppearanceElements clearly are not None./ — Kuba, Jul 04 '17 at 10:11

kglr · Accepted Answer · 2023-05-23T18:38:59.770

Using a custom icon and wrapping Manipulate with a function (based on @Kuba's method) that replaces the built-in icon with the custom one:

ClearAll[uicon, resizeU]
uicon[size_: 30] := Rasterize[Graphics[{GrayLevel[.7], Disk[], 
  Inset[Style["U", "Panel", Bold, White , FontSize -> Scaled[.7], 
   Background -> None]]}, ImageSize -> size], 
 ImageResolution -> 600, Background -> None]
resizeU[size_: 30] := RawBoxes[ToBoxes[#] /. 
  MapAt[RuleCondition, DownValues[Manipulate`ManipulateBoxes], {All, 2}] /. 
   FEPrivate`FrontEndResource["FEBitmaps", "UpdateIcon"] :> 
    ToBoxes @ uicon[size]]&;
resizeU[60] @ 
   Manipulate[10!, ContinuousAction -> None, AppearanceElements -> None]

Mathematica graphics

resizeU[]@ Manipulate[x, {x, {1, 2, 3}}, 
  AppearanceElements -> {"ResetButton", "UpdateButton", "HideControlsButton"}]

Mathematica graphics

You gave me new information. thank you very much. – Milk Jul 05 '17 at 23:17 — Milk, Jul 05 '17 at 23:17
@user21427, my pleasure. Thank you for the accept. – kglr Jul 05 '17 at 23:21 — kglr, Jul 05 '17 at 23:21

Kuba · Answer 2 · 2017-07-04T10:09:50.327

A general answer would need this to be available Can one effectively edit a Front End Resource that is already loaded?, but it is not.

Non trivial solution is to modify the boxes:

RawBoxes[
 ToBoxes[
    Manipulate[10!, AppearanceElements -> {"UpdateButton"}]
 ] /. MapAt[RuleCondition, DownValues[Manipulate`ManipulateBoxes], {All, 2}
 ] /. icon : FEPrivate`FrontEndResource["FEBitmaps", "UpdateIcon"] :> 
   RuleCondition @ ToBoxes @ Show[ToExpression @ FE`Evaluate @ icon, ImageSize -> 300
 ]
]

But as we can see the icon was designed to be small.

A better approach would be to add a custom update button:

Manipulate[10!, 
 Button[Style["U", Thick, 25], Typeset`update$$ = AbsoluteTime[], 
  Appearance -> None], AppearanceElements -> {}, TrackedSymbols :> {}]

How do I make a big update(ⓤ) button inside Manipulate?

2 Answers2