Listing what has been deleted by DeleteDuplicatesBy

Question

How can I list the items deleted from DeleteDuplicatesBy?

For example:

DeleteDuplicatesBy[{{a, b}, {f, c}, {d, b}, {e, c}, {a, c}}, Part[#, 2] &]

gives

{{a, b}, {f, c}}

However, is there any simple way to get the list {{d, b}, {e, c}, {a, c}} of deleted pairs?

At least closely related: How to get list of duplicates when using DeleteDuplicates? — Kuba, Jul 13 '17 at 06:50

score 4 · Answer 1 · answered Jul 13 '17 at 06:42

4

Here is one way.

data = {{a, b}, {f, c}, {d, b}, {e, c}, {a, c}};
p1 = DeleteDuplicatesBy[data, Part[#, 2] &]

{{a, b}, {f, c}}

p2 = DeleteCases[data, Alternatives @@ p1]

{{d, b}, {e, c}, {a, c}}

Here is another.

p2 = Complement[data, p1]

answered Jul 13 '17 at 06:42

m_goldberg

1

Note that both of these solutions fail for data with two identical items. I assume that the goal is to get a list p2 s.t. Sort[p1~Join~p2]==Sort[data] – Lukas Lang Jul 13 '17 at 06:51
@Mathe172 I am aware of the your 1st assertion, but it not clear to me the 2nd applies. – m_goldberg Jul 13 '17 at 06:54
1

@m_goldberg Although there is some problem for two identical items, it is still workable in my case as there is no identical items in my data set. Thanks a lot! – wkong Jul 14 '17 at 01:18

Carl Woll · Accepted Answer · 2017-09-09T00:17:57.827

3

Catenate @ GatherBy[
    {{a,b},{f,c},{d,b},{e,c},{a,c}},
    Last
][[All, 2;;]]

{{d, b}, {e, c}, {a, c}}

update

Here's another very similar version:

Catenate @ GroupBy[
    {{a,b},{f,c},{d,b},{e,c},{a,c}},
    Last,
    Rest
]

{{d, b}, {e, c}, {a, c}}

edited Sep 09 '17 at 00:17

answered Jul 13 '17 at 06:52

Carl Woll

score 2 · Answer 3 · answered Jan 20 '24 at 00:21

2

list = {{a, b}, {f, c}, {d, b}, {e, c}, {a, c}};

Since V 13.1 we have DeleteElements

DeleteElements[list, DeleteDuplicatesBy[Last] @ list]

{{d, b}, {e, c}, {a, c}}

DeleteElements preserves the ordering, but gets very slow with long lists

answered Jan 20 '24 at 00:21

eldo

score 1 · Answer 4 · answered Jan 20 '24 at 02:05

1

list = {{a, b}, {f, c}, {d, b}, {e, c}, {a, c}};

Using SequenceSplit:

Catenate@Rest@SequenceSplit[list, s : {a_, b_ ..} :> s]
({{d, b}, {e, c}, {a, c}})

answered Jan 20 '24 at 02:05

E. Chan-López

4 Answers4