3D Tube with large disparity in point magnitudes

Question

Consider a tube in 3D, where one of the dimensions is much flatter than the others:

pts = Table[{i, i, i/100.0}, {i, 1, 100}];
Graphics3D[Tube[pts]]

This is fine, but a bit flat - now I want it an a square box.

Graphics3D[Tube[pts], BoxRatios -> 1]

This has gone horribly wrong. How do I get a normal looking tube? Thanks

Related: https://mathematica.stackexchange.com/questions/101495/how-to-make-3-dimensional-arrows-look-good-when-their-lenghs-are-wildly-differen — smörkex, Jul 18 '17 at 01:06
One solution I have come up with is to rescale the data points so they are of equal magnitude, and then to manually relabel the tick marks. However, this isn't really a solution — smörkex, Jul 18 '17 at 03:42
I’m voting to close this question because you can't get a tube with a circular cross-section if the aspect ratio of your plot distorts circles. You will have to do some rescaling / reshaping by hand. — MarcoB, Nov 27 '20 at 17:10

score 3 · Answer 1 · answered Nov 27 '20 at 19:30

Here's another way to interpret the task to get a cube-shaped box around the plot:

cubePR[plotrange_] := 
  plotrange /. {a_, b_} :> (a + b)/2 + #/2 {-1, 1} &[
   Max[Differences /@ plotrange]];
Show[#, PlotRange -> cubePR[PlotRange@#]] &@Graphics3D[Tube[pts]]

score 2 · Answer 2 · answered Nov 27 '20 at 18:03

2

You can get a normal looking tube by giving it a reasonable radius (2nd argument to Tube).

pts = Table[{i, i, i/100}, {i, 1, 100}];
Graphics3D[Tube[pts, 5]]

answered Nov 27 '20 at 18:03

m_goldberg

107,779
16
103
257

kglr · Answer 3 · 2020-11-27T21:17:03.737

We can use Scale with parameters that depend on the BoxRatios and PlotRange to modify Tubes to look like circular independent of BoxRatios and PlotRange

ClearAll[scaledTube]
scaledTube[t_Tube, pr_, br_] := Scale[t, Normalize[-Subtract @@@ pr]/br, 
   Mean /@ CoordinateBounds[t[[1]]]]

Examples:

pts = Table[{i, i, i/100.0}, {i, 1, 100}];
tube = Graphics3D[Tube[pts, 5]]

With[{br = {1, 1, 1}, pr = {{1, 100}, {1, 100}, {0, 1}}}, 
 Labeled[Graphics3D[scaledTube[Tube[pts, 5], pr, br], 
   BoxRatios -> br, Axes -> True, PlotRange -> pr], 
  Grid[{{"box ratios: ", br}, {"plot range:", pr}}, 
   Alignment -> {Left, Center}], Top]]

versus what we get without scaling:

With[{br = {1, 1, 1}, pr = {{1, 100}, {1, 100}, {0, 1}}}, 
 Labeled[Graphics3D[Tube[pts, 5], BoxRatios -> br, Axes -> True,        
    PlotRange -> pr], 
  Grid[{{"box ratios: ", br}, {"plot range:", pr}}, 
   Alignment -> {Left, Center}], Top]]

With[{br = {1, 2, 3/2}, pr = {{1, 100}, {1, 100}, {0, 1}}}, 
 Labeled[Graphics3D[scaledTube[Tube[pts, 5], pr, br], 
   BoxRatios -> br, Axes -> True, PlotRange -> pr], 
  Grid[{{"box ratios: ", br}, {"plot range:", pr}}, 
   Alignment -> {Left, Center}], Top]]

versus no scaling:

If we replace Tube[pts, 5] with Tube[pts] in the first two examples above we get

and

somewhat related: How to force the ellipsoid of BubbleChart3D to be spherical when the BoxRatios is rectangular? — kglr, Nov 27 '20 at 20:34

score 1 · Answer 4 · answered Nov 28 '20 at 02:56

We can use the option PlotRangePadding instead of BoxRatios to get a box with desired proportions without distorting Tubes:

Grid[Partition[#, 2] &[Labeled[
    Graphics3D[{Tube[pts]},  PlotRangePadding -> #, ImageSize -> 300], 
    Style[Row[{"PlotRangePadding -> ", #}], 14], Top] & /@ 
  {Automatic, 5 {1, 1, 3}, 5 {1, 1, 10}, {5, 5, 100}}], 
 Dividers -> All]

3D Tube with large disparity in point magnitudes

4 Answers4