Finding roots of a transcendental equation

Question

Y = 2*10^11;
Iyy = 8.333*10^-6;
L = 4;
ζ = L/2;
K = 100*(Y*Iyy)/L^3;
a = (2*β^3*Sin[β*L]*Sinh[β*L]);

(*This is my main equation*)
eq1 = 
  (1 - K/(Y*Iyy) *
    ((Sin[β*(L - ζ)]*Sin[β*ζ]*Sinh[β*L] - Sinh[β*(L - ζ)]*Sinh[β*ζ]* Sin[β*L])*1/a));

P = FullSimplify[eq1];
T = P;,
Plot[T, {β, -10, 10}]

S = FindRoot[T == 0, {β, 3}] (* finding the root at 3*)
β /. % (* printing that value*)

I first plotted that equation and later, wherever it crosses the x-axis, in that neighborhood I was trying to find the root. I used FindRoot command. This program is about finding the root of the equation P.

Here its considered helpful to show your own efforts and share your code in a well formatted form instead of images or links to external files, so we can quickly Copy&Paste your code, test it, and see the problem you are facing. Please help us to help you and edit your question accordingly. This question in Meta could be useful. — rhermans, Aug 25 '17 at 09:42
The code works and there's no question asked -- what do you want? If you want a particular root, try bracketing it: FindRoot[eq1 == 0, {\[Beta], 3, 3, 4}] — Michael E2, Aug 29 '17 at 11:07
Related/duplicate: https://mathematica.stackexchange.com/questions/134106/which-root-does-findroot-give — Michael E2, Aug 29 '17 at 12:49
But when I plot my equation I did not find that function cross X axis — Nanavanalla, Aug 29 '17 at 16:13
I get this plot, if I set the PlotRange to include 0 and raise the PlotPoints to over 1000. — Michael E2, Aug 29 '17 at 17:28
You can get an idea what P looks like with Plot[Evaluate @ P, {β, -10, 10}, PlotRange -> 1.2]. It looks like it has many singularities and roots near -2 and 2. FindRoot[P == 0, {β, 2}] returns {β -> 2.34143} — m_goldberg, Aug 30 '17 at 03:40

score 3 · Accepted Answer · answered Aug 30 '17 at 11:22

3

If you want all roots in a given domain, you can use

NSolve[T == 0 && 0 < β < 10]

Clearing the trig. denominators with

NSolve[Expand[T*Cos[2 β] Sinh[4 β]] == 0 && 0 < β < 10]

is faster.

Even faster for this example is a direct search with FindRoot, bracketing the search domain to subintervals in a partition of the domain into intervals of length less than half the smallest period of the trig. functions:

Table[Check[FindRoot[T == 0, {β, n, n, n + 1}], Nothing], {n, 9}]
(* ignore errors *)

They all return

{{β -> 2.34143}, {β -> 3.92378}, {β -> 5.49661}, {β -> 7.06803}, {β -> 8.63908}}

answered Aug 30 '17 at 11:22

Michael E2

235,386
17
334
747

1

You can use Quiet[] to suppress the printing of the FindRoot errors, but I feel on this educational forum that unless the question is about suppressing them, it is better for the users to see them and think about whether they are serious or can be ignored. – Michael E2 Aug 30 '17 at 11:48
Thanks, MichaelE2 (best answer) and also m_goldberg. – Nanavanalla Aug 31 '17 at 15:41
@VijayKumarS It is a good practice to accept the most helpful answer, you know... – Henrik Schumacher Jan 08 '18 at 16:20

Finding roots of a transcendental equation

1 Answers1