Inserting some zeros in a list by a rule of positions

Question

I have a list:

mainlist={0.23, 0.34, 0.8, 0.0, -0.2, 0.4, -0.1};

I have to extend the above list to another one finalresult with Length=17. But in finalresult the elements of the mainlist must be in the positions ruled by the positionlist:

positionlist={3,4,8,9,10,13,14};

finalresult={0,0,0.23,0.34,0,0,0,0.8,0.0,-0.2,0,0,0.4,-0.1,0,0,0}

How can I reach this goal? I would be so glad to see an answer.

I expect somebody to reference a duplicate, but you can use finalresult = ConstantArray[0, 17]; finalresult[[positionlist]]=mainlist in the meantime. — Carl Woll, Aug 26 '17 at 14:23
@CarlWoll I looked but I was unable to find a duplicate. Perhaps you would care to convert your comment to an answer, in the mean time. :^) — Mr.Wizard, Aug 26 '17 at 21:33

John Joseph M. Carrasco · Accepted Answer · 2017-08-26T14:49:03.593

16

Normal@SparseArray[Thread[positionlist -> mainlist], 17, 0]

Update: should emphasize C.E.'s nice comment:

Normal@SparseArray[positionlist -> mainlist, 17]

equivalent in result, more pleasantly laconic, and lack of explicit thread actually less expensive for longer lists.

edited Aug 26 '17 at 14:49

answered Aug 26 '17 at 14:26

John Joseph M. Carrasco

3,190
12
19

7

+1. Thread and the zero at the end can be omitted. – C. E. Aug 26 '17 at 14:27
1

A usage note regarding the performance of this method: (148112) – Mr.Wizard Aug 26 '17 at 21:15

score 7 · Answer 2 · answered Aug 26 '17 at 16:50

mainlist={0.23, 0.34, 0.8, 0.0, -0.2, 0.4, -0.1};
positionlist={3,4,8,9,10,13,14};

ReplacePart[ConstantArray[0, 17], Thread[positionlist -> mainlist]]

or what @Carl Woll suggested:

finalresult = ConstantArray[0, 17];
finalresult[[positionlist]] = mainlist

score 3 · Answer 3 · answered Jan 14 '24 at 00:09

3

list = {0.23, 0.34, 0.8, 0.0, -0.2, 0.4, -0.1};

p = {3, 4, 8, 9, 10, 13, 14};

Using SubsetMap (new in 12.0)

SubsetMap[list &, Table[0, 17], p]

{0, 0, 0.23, 0.34, 0, 0, 0, 0.8, 0., -0.2, 0, 0, 0.4, -0.1, 0, 0, 0}

answered Jan 14 '24 at 00:09

eldo

67,911
5
60
168

score 2 · Answer 4 · answered Jan 14 '24 at 03:36

Using Fold:

Clear["Global`"];
mainlist = {0.23, 0.34, 0.8, 0.0, -0.2, 0.4, -0.1};
positionlist = {3, 4, 8, 9, 10, 13, 14};
rules = Rule @@@ Transpose[{positionlist, mainlist}];
Fold[ReplacePart[#1, #2] &, Table[0, 17], rules]

{0, 0, 0.23, 0.34, 0, 0, 0, 0.8, 0., -0.2, 0, 0, 0.4, -0.1, 0, 0, 0}

score 1 · Answer 5 · answered Jan 14 '24 at 18:07

list = {0.23, 0.34, 0.8, 0.0, -0.2, 0.4, -0.1};

p = {3, 4, 8, 9, 10, 13, 14};

An alternative using Cases and If:

rep = Rule @@@ Thread[{p, list}];
Cases[Range[17], x_ :> If[And @@ (Unequal[x, #] & /@ p), 0, x /. rep]]
({0, 0, 0.23, 0.34, 0, 0, 0, 0.8, 0., -0.2, 0, 0, 0.4, -0.1, 0, 0, 0})

Inserting some zeros in a list by a rule of positions

5 Answers5