How to assign two sets of colors for two `ParametricPlot`?

Question

I would like to use ParametricPlot twice and use Show to put them together:

p1 = ParametricPlot[ 
  Evaluate@
   Table[ReIm[r ( Cos[u] + I  Sin[u])], {r, Range[0.1, 0.9, .2]}],
  {u, -Pi/2, 3 Pi/2},
  PlotStyle -> Thick,
  PlotRange -> 1.2,
  AxesStyle -> Opacity[0.2],
  ImageSize -> 300]

p2 = ParametricPlot[ 
  Evaluate@
   Table[ReIm[
     r ( Cos[u] + I  Sin[u])], {u, {Pi/6, 3 Pi/4, 5 Pi/4, -Pi/4}}],
  {r, 0.01, 0.9999},
  PlotStyle -> {Thick},
  PlotRange -> 1.2,
  AxesStyle -> Opacity[0.1],
  ImageSize -> 300]

One can see that the four colors in p2 are the same as the first four colors in p1. How can I make p2 with a set of colors different from that of p1?

One might manually choose different colors for lines in p2. I'm interested in a way that makes colors in p1 and p2 look as if they are from one ParametricPlot.

Young · Accepted Answer · 2017-09-21T01:16:36.987

4

Use PlotStyle and ColorData to specify the color of the lines.

p1

PlotStyle -> Table[ColorData[97, i], {i, 1, 5}]

p2

PlotStyle -> Table[ColorData[97, i], {i, 6, 9}]

All together:

Show[
 p1 = ParametricPlot[
   Evaluate@
    Table[ReIm[r (Cos[u] + I Sin[u])], {r, Range[0.1, 0.9, .2]}], {u, -Pi/2, 3 Pi/2}, 
   PlotStyle -> Table[Directive[Thick, ColorData[97, i]], {i, 1, 5}], 
   PlotRange -> 1.2, AxesStyle -> Opacity[0.2], ImageSize -> 300],
 p2 = ParametricPlot[
   Evaluate@
    Table[ReIm[r (Cos[u] + I Sin[u])], {u, {Pi/6, 3 Pi/4, 5 Pi/4, -Pi/4}}], {r, 0.01, 0.9999}, 
   PlotStyle -> Table[Directive[Thick, ColorData[97, i]], {i, 6, 9}], 
   PlotRange -> 1.2, AxesStyle -> Opacity[0.1], ImageSize -> 300]
 ]

edited Sep 21 '17 at 01:16

answered Sep 21 '17 at 01:10

Young

7,495
1
20
45

Thanks. Is there something special about that 97? – Sep 21 '17 at 01:29
1

97 is the default color palette used by Mathematica – Young Sep 21 '17 at 01:30
1

Found this related: https://mathematica.stackexchange.com/a/54632/664 Thanks! – Sep 21 '17 at 02:21

score 2 · Answer 2 · answered Sep 21 '17 at 02:34

Thanks to @Young's answer, I see that it might be a better idea to use another color "scheme" for p2, so that the colors would look more different from those in p1:

p1 = ParametricPlot[ 
  Evaluate@
   Table[ReIm[r ( Cos[u] + I  Sin[u])], {r, Range[0.1, 0.9, .2]}],
  {u, -Pi/2, 3 Pi/2},
  PlotStyle -> 
   Table[Directive[Thickness[0.01], ColorData[97, i]], {i, 1, 5}],
  PlotRange -> 1.2,
  AxesStyle -> Opacity[0.2],
  ImageSize -> 250]

p2 = ParametricPlot[ 
  Evaluate@
   Table[ReIm[
     r ( Cos[u] + I  Sin[u])], {u, {Pi/6, 3 Pi/4, 5 Pi/4, -Pi/4}}],
  {r, 0.01, 0.9999},
  PlotStyle -> 
   Table[Directive[Thickness[0.01], ColorData[101, i]], {i, 6, 9}],
  PlotRange -> 1.2,
  AxesStyle -> Opacity[0.1],
  ImageSize -> 250]

How to assign two sets of colors for two `ParametricPlot`?

2 Answers2