Import of a SubRip file

Question

How can you import a SubRip file?

I tried plain Import[] but it did not work.

Unfortunately I can't attach a SRT example, but you can find SubRip files on edX.

Here is a description: https://fileinfo.com/extension/srt

b3m2a1 note:

Here's a sample, coming from here:

1 
00:02:17,440 --> 00:02:20,375
Senator, we're making our final approach into Coruscant.

2 
00:02:20,476 --> 00:02:22,501
Very good, Lieutenant.

Please add more information, e.g. format descriptions/specifications and also sample data. Currently, this question is not very accessible. — Yves Klett, Oct 16 '17 at 09:55
@totyped can you add some real data? Even like the plaintext form of that screenshot — b3m2a1, Oct 16 '17 at 21:38
That's SubRip, not SubRib! Now you see why it was important to at least link to the description? — Szabolcs, Oct 16 '17 at 21:46

b3m2a1 · Accepted Answer · 2017-10-17T06:24:00.440

Absent any data, from that image, here's what I'd try:

srtImport[f_String?FileExistsQ] :=
 srtImport[Import[f, "Text"]]

srtImport[s_String] :=
 StringCases[s,
  Shortest[
    n : NumberString ~~ Except["\n", WhitespaceCharacter] ... ~~ "\n" ~~

     ts : Except[WhitespaceCharacter] .. ~~ " --> " ~~ 
     ts2 : Except[WhitespaceCharacter] .. ~~ Except["\n", WhitespaceCharacter] ... ~~ 
     "\n" ~~ desc___ ~~ ("\n\n"|EndOfString)
    ] :>
   n -> <|
     "Segment" -> n,
     "StartTime" -> TimeObject@StringReplace[ts, "," -> "."],
     "EndTime" -> TimeObject@StringReplace[ts2, "," -> "."],
     "Description" -> desc
     |>
  ]

Here is that applied to the sample:

srtSamp = "1
  00:02:17,440 --> 00:02:20,375
  Senator, we're making our final approach into Coruscant.

  2
  00:02:20,476 --> 00:02:22,501
  Very good, Lieutenant.";

srtImport[srtSamp] // Association // Dataset

Thank you very much!! This is an awesome solution! :) – james Oct 17 '17 at 11:21 — james, Oct 17 '17 at 11:21

Import of a SubRip file

1 Answers1

Linked