Integral of $1/x$ with x real in Mathematica

Question

I'd like to get:

$$\int \frac{1}{x} dx = \log |x|$$

in Mathematica. I don't know how impose that $x$ is real. If I run:

Integrate[1/x,x]

Mathematica gives me $\log (x)$ without absolute value because it considers $x$ as a complex number.

Thank you in advance for your help.

Why do you want it to give you this answer? Given Mathematica's definition of Log its answer is correct for negative values. If you can explain the problem Mathematica's answer gives you, we may be able to suggest a work around. — mikado, Oct 29 '17 at 13:49
Cross-posted at community.wolfram. Could you please provide a link? — Michael E2, Oct 29 '17 at 21:26

score 2 · Accepted Answer · answered Oct 29 '17 at 15:19

You can define your own function to do so:

realIntegrate[f_, x_Symbol] := 
  Simplify[Integrate[f, x] /. Log[expr_] :> Log[Abs[expr]], x ∈ Reals]

realIntegrate[1/x, x]

(* Log[Abs[x]] *)

realIntegrate[2x/(x^2 - 1), x]

(* Log[Abs[x^2 - 1]] *)

realIntegrate[2x/(x^2 + 1), x]

(* Log[x^2 + 1] *)

Or if you need Integrate to do this, you can overload its definition:

Unprotect[Integrate];

Integrate[f_, x_Symbol] /; !TrueQ[$flag] := 
  Block[{$flag = True},
    realIntegrate[f, x]
  ]

Protect[Integrate];

Integrate[1/x, x]

(* Log[Abs[x]] *)

Integrate[2x/(x^2 - 1), x]

(* Log[Abs[x^2 - 1]] *)

Integrate[2x/(x^2 + 1), x]

(* Log[x^2 + 1] *)

In this specific use case, RealAbs[] is much better to use than Abs[]. — J. M.'s missing motivation, Oct 31 '17 at 06:06

Integral of $1/x$ with x real in Mathematica

1 Answers1

Linked