How to change the label "Evaluating Initialization..." when SynchronousInitialization -> False?

Question

I frequently use SynchronousInitialization -> False when I have time consuming initialization in a Manipulate expression. I was wondering how I could change the label "Evaluating Initialization..." to, say, "Wait please..."?

Manipulate[x, 
 {x, 0, 1}, 
 SynchronousInitialization -> False, 
 Initialization :> (Pause[1])]

Answer 1

not recommended approach

With Method -> {"TemplateExpand" -> True} you can inspect whole structure of created boxes.

ToBoxes[Manipulate[body
, SynchronousInitialization -> False
, Initialization :> (Pause[1])
, Method -> {"TemplateExpand" -> True}
]]

and find out that this preview is defined in Manipulate`Dump`initDisplay. So here's a quick helper function to replace it:

replaceInitScreen[
  manipulate_,
  newInit_
] := RawBoxes[
  ToBoxes[manipulate] /. 
   HoldPattern[Manipulate`Dump`initDisplay[False]] -> newInit
]

replaceInitScreen[
 Manipulate[body, SynchronousInitialization -> False, 
  Initialization :> (Pause[1]), Method -> {"TemplateExpand" -> True}],
 Row[{ProgressIndicator[Appearance -> "Percolate"], "Please wait..."}]
 ]

It works but it is not a recommended way, consider it an exercise.

recommended approach

What you should do it to take it in your hands and do something like:

DynamicModule[{initDone = False}
, Panel @ Dynamic[
    If[ Not @ TrueQ @ initDone
    , Row[{ProgressIndicator[Appearance -> "Percolate"], "Please wait..."}]
    , body
    ]
  , TrackedSymbols :> {initDone}
  ]
, UnsavedVariables :> {initDone}
, SynchronousInitialization -> False
, Initialization :> (Pause[1]; body = "whatever"; initDone = True)
]

Read more in closely related:

Working with DynamicModule: Tracking the progress of Initialization