How make AddMenuCommands work in an init.m

Question

I want to add some items to the Mathematica 8.0.4 Help menu (under Mac OS X). In

 [$UserBaseDirectory]/Autoload/FrontEnd/init.m

I have the following cell:

  FrontEnd`AddMenuCommands["OpenHelpLink",{Delimiter,
  Item["Installed Add-Ons",FrontEndExecute[FrontEnd`FrontEndToken["OpenHelpLink",    
       {"guide/InstalledAddOns",Automatic}]]],
  Item["Standard Extra Packages",FrontEndExecute[FrontEnd`FrontEndToken["OpenHelpLink", 
        {"guide/StandardExtraPackages",Automatic}]]],
  Delimiter}]

but the items are not added to the Help menu when I start Mathematica.

Do I have the syntax wrong, or should this go in some other init.m?

Answer 1

I can only speak for Windows but I would expect the solution should be similar for Mac.

I created a file $BaseDirectory\FrontEnd\init.m

In that file I added the following lines. Note they are slightly different than what you provide but should do what you want.

FrontEndExecute[AddMenuCommands["AboutBoxDialog",{Delimiter,
  Item["Installed Add Ons",FrontEndExecute[FrontEnd`FrontEndToken["OpenHelpLink",
    {"guide/InstalledAddOns",Automatic}]]],Item["Standard Extra Packages",
       FrontEndExecute[FrontEnd`FrontEndToken["OpenHelpLink",
          {"guide/StandardExtraPackages",Automatic}]]]}]]

I attempted to do this using $UserBaseDirectory\FrontEnd but Mathematica insists on wiping out any changes I make to the init.m file that already exists there.

EDIT:

Following the comment by @Matariki one can place the init.m file in $UserBaseDirectory\Autoload\PacletManager\Configuration\FrontEnd\ instead. I'm not sure which is preferable. The $BaseDirectory installation should add the customization for any user on the machine whereas the $UserBaseDirectory option will only work for the selected user.

Extension:

Also worth noting is that "AboutBoxDialog" is a front end token that can be found in MenuSetup.tr located in $InstallationDirectory/SystemFiles/FrontEnd/TextResources/.

These tokens, to my knowledge, are the only way to control the placement of new commands in menus. I could for example have added a background color to the Format>Background Colors menu by noting that "BackgroundDialog" is the token closest to the relevant menu in MenuSetup.tr. Adding the following code to the previously mentioned init.m will add a Linen color to the Background Colors sub-menu.

FrontEndExecute[ 
  AddMenuCommands["BackgroundDialog", {Delimiter, 
   Item["L&inen",Background->RGBColor[0.980,0.941,0.902]]}]];