Event action default before custom

Question

I want to change how a notebook files save. The basic framework I'm using for this is:

SetOptions[
 EvaluationNotebook[],
 NotebookEventActions ->
  {
   {"MenuCommand", "Save"} :>
    (NotebookSave[]; $action)
   }
 ]

Because with PassEventsDown->True the $action gets called before the NotebookSave.

This is ugly and a little bit hazardous, though. Is there any way to have it otherwise? Can I trigger the event to save first, then do the $action with PassEventsDown->True?

Answer 1

So I found the answer to this in an old answer of mine. The trick is to use the undocumented EvaluationOrder.

By assigning EvaluationOrder->After our event gets called after the built-in one. To test this we can try the following. First, see what happens with "ModifiedInMemory" with the explicit order we started with:

SetOptions[
 EvaluationNotebook[],
 NotebookEventActions ->
  {
   {"MenuCommand", "Save"} :>
    (
     NotebookSave[];
     Print[Lookup[NotebookInformation[], "ModifiedInMemory"]]
     )
   }
 ]

(* prints False on save events *)

With no EvaluationOrder:

SetOptions[
 EvaluationNotebook[],
 NotebookEventActions ->
  {
   {"MenuCommand", "Save"} :>
    (
     Print[Lookup[NotebookInformation[], "ModifiedInMemory"]]
     ),
   PassEventsDown -> True
   }
 ]

(* prints True on save events *)

With no EvaluationOrder->After:

SetOptions[
 EvaluationNotebook[],
 NotebookEventActions ->
  {
   {"MenuCommand", "Save"} :>
    (
     Print[Lookup[NotebookInformation[], "ModifiedInMemory"]]
     ),
   PassEventsDown -> True,
   EvaluationOrder->After
   }
 ]

(* prints False on save events *)

This also works for EventHandler and CellEventActions