How to draw a shaded elipse using drawing tools?

Question

I'm trying to draw the following picture using drawing tools, but I could get just the arrows and points.

As you can imagine, I'm a begginer at mathematica, but I use LaTeX. I'd like to know if there is a nice reference for commands. I imaggine that we can't draw every thing with drawing tools, just simple figures, like this one.

MMA is not a graphics arts software. It can produce nice graphs/plots, but often companions of mathematical calculations... Anyway take a look at this — José Antonio Díaz Navas, Jan 25 '18 at 15:54
Create the half ellipse, then use this to get the gradient (think of it as a green shadow.) — C. E., Jan 25 '18 at 16:12
I drow the 24 arrows with drawing tools, how do I do what you sugget with drawing tools? If not possible, how to draw these arrows at Graphics[]? Do I have to write Arrow[] 24 times? — geekformoney, Jan 25 '18 at 17:24
With the drawing tools, this is not possible. You need to do programming (rasterize the ellipse, blur it, etc.) That programming is going to be more work than what it would take to do this with a proper drawing program. There are free ones, like Inkscape. — Szabolcs, Jan 25 '18 at 17:34

C. E. · Accepted Answer · 2018-01-25T18:43:31.623

5

I'll build on David's answer (if you vote for this one, please also vote for his), since it's been a while since anyone demonstrated the excellent shadow` package on this site.

We start by defining the arrows as in the previous answer:

myarrow[x_, y_] := Graphics[{
    Purple,
    Thickness[0.02],
    Arrowheads[.08],
    Arrow[{{x, y}, {x, y - 1.5}}],
    Black,
    PointSize[0.04],
    Point[{x, y}]
    }];
arrows = Show[Table[myarrow[x, y], {x, 0, 7, 1}, {y, 0, -4, -2}]];

Then we create the half ellipse:

myGreen = RGBColor[{165, 203, 149}/255];
ellipse = Graphics[{
   myGreen,
   DiskSegment[{0, 0}, {5, 1}, {Pi, 2 Pi}]
   }, ImageSize -> 600]

Mathematica graphics

Now we use the shadow` package to blur the ellipse:

<< shadow`

glowingEllipse = shadow[
  ellipse,
  ellipse,
  "blur" -> 30,
  "offset" -> {0, 0},
  "color" -> myGreen,
  "outline" -> False
  ]

Mathematica graphics

Finally, we put the arrow and the half ellipse together. We also add the gray line:

Show[
 arrows,
 Graphics[{
   Inset[glowingEllipse, {3.5, -5.5}, {Center, Top}, {10, 2}],
   Thick, Lighter@Gray,
   Line[{{-0.8, -6}, {7.8, -6}}]
   }]
 ]

Mathematica graphics

edited Jan 25 '18 at 18:43

answered Jan 25 '18 at 18:29

C. E.

70,533
6
140
264

How do I call a package for the entire notebook? I'm writing a textbook – geekformoney Jan 25 '18 at 18:42
@geekformoney You can load it (using << shadow`) anywhere in the notebook. – C. E. Jan 25 '18 at 18:44
and how do i install this package? – geekformoney Jan 25 '18 at 18:44
1

@geekformoney There is information about that in the footer of this website. – C. E. Jan 25 '18 at 18:46
nice. sorry to bother all of you with such simple questions, i'm a noob beginner. I never heard about this site for mathematica packages. – geekformoney Jan 25 '18 at 18:50
@geekformoney Don't worry about it, we were all beginners once. (Although sometimes we don't remember what it was like.) – C. E. Jan 25 '18 at 18:55

David G. Stork · Answer 2 · 2018-01-25T18:48:01.180

3

myarrow[x_, y_] := 
  Graphics[{Purple, Thickness[0.02], Arrowheads[.08], 
    Arrow[{{x, y}, {x, y - 1.5}}], Black, PointSize[0.04], 
    Point[{x, y}]}];
myellipse = Graphics[
   DensityPlot[(x - 4)^2 + (y - 4)^2, {x, 0, 7}, {y, -6, -9},
    Frame -> None,
    AspectRatio -> 1/2]
   ];
 Show[Table[myarrow[x, y], {x, 0, 7, 1}, {y, 0, -4, -2}],
  myellipse]

Play with the ColorFunction to get your desired green.

edited Jan 25 '18 at 18:48

answered Jan 25 '18 at 17:26

David G. Stork

41,180
3
34
96

can this be used inside Graphics[]? – geekformoney Jan 25 '18 at 17:37
@geekformoney: What do you mean by "this"? One typically uses or defines an abstract object outside of Graphics[], and then renders it visually through a call by Graphics. – David G. Stork Jan 25 '18 at 17:51
Graphics[Table[myarrow[x, y], {x, 0, 7, 1}, {y, 0, -4, -2}], ellipse commands] – geekformoney Jan 25 '18 at 18:42

How to draw a shaded elipse using drawing tools?

2 Answers2