Change order of evaluation in Plot[] nested with NDSolve[]

Question

I noticed that in Plot the function is evaluated at each sample point

Plot[func@x,{x,rStart1,rEnd1}]

which is fine for a regular function. If I substitute the function with an NDSolve, the problem is that at every sample point the NDSolve is evaluated so it is time consuming.

Plot[NDSolve[(*diff equation*)][[1]]@x,{x,rStart1,rEnd1}]

I find a workaround to NDSolve only once, and pass it to the Plot[].

NDSolve[(*diff equation*)][[1]] //Plot[#@x, {x, rStart1, rEnd1}] &

I just wonder if there is a better way to do it, for example to Hold/Release or some magical trick to force it only being evaluated once.

possibly of interest: Plotting the sum of curves without recalculation. — AccidentalFourierTransform, Feb 09 '18 at 15:19
Related: https://mathematica.stackexchange.com/questions/134222/easy-way-to-plot-ode-solutions-from-ndsolve — Michael E2, May 29 '18 at 19:57

score 2 · Answer 1 · answered May 29 '18 at 16:58

Two alternatives that would evaluate only once.

Let's verify that by using a counter

counter = 0;
Dynamic[counter]

`With`

With[
 {
  func = NDSolve[
     counter += 1;
     {y'[x] == y[x] Cos[x + y[x]], y[0] == 1}
     , y
     , {x, 0, 30}
     ][[1, 1, 2]]
  },
 Plot[
  func[x]
  , {x, 0, 30}
  , PlotRange -> All]
 ]

`Evaluate`

Plot[
 Evaluate[
  y[x] /. NDSolve[
    counter += 1;
    {y'[x] == y[x] Cos[x + y[x]], y[0] == 1}
    , y
    , {x, 0, 30}
    ]]
 , {x, 0, 30}
 , PlotRange -> All
 ]

Mathematica graphics

score 2 · Answer 2 · answered May 29 '18 at 20:01

2

Perhaps the easiest way in V9+ is

ListLinePlot@ NDSolve[(*ode for y[x]*), y, x]

Example from @rhermans:

ListLinePlot@ 
 NDSolveValue[{y'[x] == y[x] Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30}]

Mathematica graphics

answered May 29 '18 at 20:01

Michael E2

235,386
17
334
747

Change order of evaluation in Plot[] nested with NDSolve[]

2 Answers2

With

Evaluate

`With`

`Evaluate`