`NotebookEventActions` for special keys ("F2", "F3", "pause", etc.) on Windows

Question

Using NotebookEventActions one can make MMA evaluate a function when a key is pressed. For example:

SetOptions[
  EvaluationNotebook[],
  NotebookEventActions -> {{"KeyDown","x"} :> Print["You pressed \"x\"!"]}
]

will print a sentence every time the user presses "x" on the keyboard.

How do I use NotebookEventActions to do something when the user presses one of the function keys "F2", "F3, ..., "F12", or a special key, such as "pause"?

If this is not possible, then how can I make my program react to special keys with a mechanism other than NotebookEventActions? It is important that the change is local to one notebook, and that it can be made programmatically.

Answer 1

This should work:

CellPrint[
 Cell[BoxData["\"Try the function keys\""],
  "Output",
  CellEventActions -> {
    {"KeyDown", "\.10"} :> Print["this should work"]
    },
  CellEditDuplicate -> False
  ]
 ]

I found that by using this trick

CellPrint[
 Cell[BoxData["\"Type here to determine key type\""],
  "Output",
  CellEventActions -> {
    "KeyDown" :>
     (
      SelectionMove[EvaluationCell[], All, CellContents];
      NotebookWrite[EvaluationNotebook[],
       ToBoxes[
          <|
           "Name" -> CharacterName[#, "UnicodeName"],
           "Display" -> #,
           "KeyRaw" -> FullForm[#]
           |>
          ] &@CurrentValue["EventKey"]
       ]
      )
    },
  CellEditDuplicate -> False
  ]
 ]