How do I extract a number from a string?

Question

I want to extract the number from an alphanumeric string. This is what I tried:

StringTake["thiru3", {6, 6}]

The result I got is 3, but it is still a String, which I determined by evaluating:

NumberQ[StringTake["thiru3", {6, 6}]]

which returns False.

Related or possible duplicate: How do you convert a string containing a number in C scientific notation to a Mathematica number? — Mr.Wizard, Feb 27 '13 at 04:04
@Mr.Wizard. I don't think it's a duplicate. This is about extracting a simple integer, not about a real an encoded in a string. — m_goldberg, Feb 27 '13 at 06:04

score 19 · Answer 1 · answered Dec 22 '12 at 10:30

19

 StringCases["thiru3", x : NumberString :> ToExpression[x]]
 (* {3} *)
 First[%]
 (* 3 *)
 {NumberQ[%], Head[%]}
 (* {True, Integer} *)

answered Dec 22 '12 at 10:30

kglr

394,356
18
477
896

1

As noted by ssch in Chris's answer, FromDigits[] might be better to use than ToExpression[]. – J. M.'s missing motivation Apr 04 '13 at 14:55
1

NumberString will match real number strings and FromDigits will balk; ToExpression will convert them. I would say NumberString & ToExpression for real numbers, or, for integers only, DigitCharacter.. and FromDigits. You won't get messages in either case, as in ssch's comment, because FromDigits is called only when there is a match. – Michael E2 Oct 16 '13 at 12:09

score 12 · Answer 2 · answered Dec 22 '12 at 10:21

12

Try to use ToExpression, like this

ToExpression[StringTake["thiru3", {6, 6}]]

If you check it with Head[%] it confirms that it is an Integer

answered Dec 22 '12 at 10:21

Crown42

463
2
8

Chris Degnen · Answer 3 · 2013-04-30T14:54:36.010

11

Alternatively, and for multiple numbers:-

Map[FromDigits, Select[Characters["thiru37"], DigitQ]]

{3, 7}

Latterly

ToExpression@StringCases["thiru37", DigitCharacter]

{3, 7}

edited Apr 30 '13 at 14:54

answered Dec 22 '12 at 12:36

Chris Degnen

30,927
2
54
108

2

I think FromDigits is the best way since you will immediatly get a message printed in case it didn't work, that you can Check for if need be – ssch Dec 22 '12 at 19:23

score 9 · Answer 4 · answered Oct 16 '13 at 10:21

9

Here is one compact option

Internal`StringToDouble@"thiru3"

3.

answered Oct 16 '13 at 10:21

Murta

26,275
6
76
166

Nice - where the heck did you get that from? – Yves Klett Oct 16 '13 at 15:03
Ahh.. I was looking for a faster way to make conversions from string to numbers, and found it here – Murta Oct 16 '13 at 22:15

score 3 · Answer 5 · answered Feb 27 '13 at 03:41

Like NumberString, DigitCharacter can be used to find numbers in a string. Use relative positioning in the string (like EndOfString) to localize your digits and ignore other numbers possibly appearing at other positions:

First@StringCases["0thi12ru3", (n:DigitCharacter~~EndOfString) :> ToExpression@n]

(* ==> 3 *)

This searches for exactly one number character right before the end of string. If the terminal number could have more than one digits, use DigitCharacter.. instead.

ubpdqn · Answer 6 · 2013-10-16T11:41:00.570

3

Consider:

str = "thiru37aa2er45"

then

StringCases[str, DigitCharacter ..]

yields:

{"37", "2", "45"}

StringCases[str, DigitCharacter .]

yields:

{"3", "7", "2", "4", "5"}

They can be converted to expressions using ToExpression

edited Oct 16 '13 at 11:41

answered Oct 16 '13 at 11:12

ubpdqn

60,617
3
59
148

1

StringCases["thiru37aa2er45", x : DigitCharacter .. :> FromDigits[x]] – Mr.Wizard Oct 16 '13 at 11:15
@Mr.Wizard thank you...all in one step – ubpdqn Oct 16 '13 at 11:40

score 2 · Answer 7 · answered Dec 22 '12 at 23:03

2

s = "thiru3";
r = First@StringCases[s, RegularExpression["\\d+"]];
Needs["JLink`"];
InstallJava[];
LoadJavaClass["java.lang.Integer"];
z = Integer`parseInt[r]
Head[z]

Mathematica graphics

answered Dec 22 '12 at 23:03

Nasser

143,286
11
154
359

bbbut... why not ToExpression@r? – rm -rf Dec 22 '12 at 23:07
1

@rm-rf The sarcasm character doesn't display in your browser I guess. – Sjoerd C. de Vries Dec 22 '12 at 23:13
5

wish I could upvote twice. what an economical solution – acl Dec 23 '12 at 00:50

score 1 · Answer 8 · answered Oct 16 '13 at 09:39

1

Can be so

ToExpression[StringCases["thiru3", DigitCharacter ..]][[1]]

or

ToExpression[
  StringCases["thiru3", "thiru" ~~ (x : DigitCharacter ..) -> x]][[1]]

or

ToExpression[StringCases["thiru3", RegularExpression["\\d+"]][[1]]]

answered Oct 16 '13 at 09:39

Alexandr Shamshin

11
1

score 0 · Answer 9 · answered Feb 27 '13 at 05:33

0

Try this.

Read[StringToStream[StringTake["thiru3", {6, 6}]]]

answered Feb 27 '13 at 05:33

subbu

2,304
1
13
32

How do I extract a number from a string?

9 Answers9

Linked