How to catch error messages from parallel kernels

Question

Doing something that throws out an error (warning):

ParallelTable[NIntegrate[1/Sin[10 t], {t, 0, W}], {W, 0, 10, 1}]

In parallel somehow limits a possiblity to harvest error messages like I usually do:

myMessageList = {};
Internal`InheritedBlock[{Message, $InMsg = False}, Unprotect[Message];
Message[msg_, vars___] /; ! $InMsg := 
Block[{$InMsg = True}, 
AppendTo[myMessageList, {HoldForm[msg], vars}];
Message[msg, vars]];
ParallelTable[NIntegrate[1/Sin[10 t], {t, 0, W}], {W, 0, 10, 1}]] (*this is the string that is being executed*)
myMessageList

This works for Table just fine. Is there a way to avoid that? What I really need is to discard any output that produces an error.

Somewhat related: https://mathematica.stackexchange.com/questions/27262/how-can-you-link-parallel-mapping-and-error-tracking — Michael E2, Mar 25 '18 at 00:44
@MichaelE2 that tags error messages just fine, but how do I harvest them into some list for example? — Vsevolod A., Mar 25 '18 at 00:50
I don't know to answer the other question. I just thought the two questions were similar enough that linking them might be helpful. Please see if my answer solves your problem. — Michael E2, Mar 25 '18 at 01:53

score 4 · Accepted Answer · answered Mar 25 '18 at 01:52

Two changes make it work. Collect the messages on each subkernel and alter Message on each subkernel. The messages can be harvested with ParallelEvaluate.

ParallelEvaluate[myMessageList = {}];
ParallelTable[
 Internal`InheritedBlock[{Message, $InMsg = False},
  Unprotect[Message];
  Message[msg_, vars___] /; ! $InMsg := Block[{$InMsg = True},
    AppendTo[myMessageList, {HoldForm[msg], vars}];
    Message[msg, vars]];
  NIntegrate[1/Sin[10 t], {t, 0, W}]
  ],
 {W, 0, 10, 1}]
ParallelEvaluate[myMessageList]  (* Flatten[%, 1] if desired *)

How to catch error messages from parallel kernels

1 Answers1