How to stop Animate animation when reaching a defined value

Question

I have following code

Animate[
Plot[myvariable x,{x,0,100}
],
{myvariable,0.1,1},AnimationRunning->If[myvariable==1,False,True]
]

How do I make the animation stop automatically when reaching a defined value?

NOTE: I tried to make it stop by evaluating myvariable in a If expression, but I get the error "An unrecognized option name ("AnimationRunning") was encountered while reading a AnimatorBox."

Given your example, you could just set AnimationRunning -> True, AnimationRepetitions -> 1 — Jens, Jan 10 '13 at 19:31
Post is an answer an I will mark as the answer, Thanx for answering so fast :D — elhombre, Jan 10 '13 at 19:34

score 7 · Answer 1 · answered Jan 11 '13 at 01:06

7

Mathematica is very flexible when it comes to these sorts of things. You can easily build your own little animation, and add as much complexity to the logic of termination by using Dynamic directly.

For example, this plots Cos[a x] and stops the animation when a>0.2.

Clear[p];
Dynamic[p]
Do[p = Plot[Cos[a x], {x, 0, 100}, Frame -> True, 
   FrameLabel -> {{None, None}, {x, 
      Style[Column[{"doing my own animation !", Cos[a x]}, 
        Alignment -> Center], 14]}}, GridLines -> Automatic];
 If[a > 0.2, Break[]]; (*condition to stop*)
 Pause[.2],
 {a, 0.1, 1, .01}
 ]

Mathematica graphics

answered Jan 11 '13 at 01:06

Nasser

143,286
11
154
359

2

+1 for a method I really don't think I would have considered. – Mr.Wizard Jan 11 '13 at 01:11
1

+1 Because you did the work to allow a more general stopping condition than the question asked for. – Jens Jan 11 '13 at 01:34

score 3 · Accepted Answer · answered Jan 10 '13 at 20:42

The condition in your case is to stop at the maximum value of the parameter. This can be achieved by setting the number of animation repetitions to 1 (i.e., no looping):

Animate[Plot[myvariable x, {x, 0, 100}], {myvariable, 0.1, 1}, 
 AnimationRunning -> True, 
 AnimationRepetitions -> 1
]

How to stop Animate animation when reaching a defined value

2 Answers2

Linked