How to avoid applying Cross to a single argument?

Question

I am looking for the simplest way to avoid applying Cross to a single argument.

PrimeFactorization[x_] := Cross @@ (Superscript @@@ FactorInteger[x]);
Table[{n, PrimeFactorization[n]}, {n, 200, 250}] // TableForm

Down vote detected. Thank you! – Friendly Ghost Aug 17 '18 at 12:55 — Friendly Ghost, Aug 17 '18 at 12:55

score 10 · Answer 1 · answered Aug 16 '18 at 08:04

10

If it is only for displaying purposes you can use Row:

PrimeFactorization[x_] := Row[#, "\[Cross]"] & @ (Superscript @@@ FactorInteger[x])

answered Aug 16 '18 at 08:04

Kuba

136,707
13
279
740

This solution is not TeXForm friendly. Thank you! – Friendly Ghost Aug 16 '18 at 08:10
9

@FriendlyGhost there is nothing about TeXForm in your question. – Kuba Aug 16 '18 at 08:12
@FriendlyGhost, use BoxForm`$UseTemplateSlotSequenceForRow = False; before using TeXForm on expressions involving Row.(See Incompatibility of Row and TeXForm) – kglr Aug 17 '18 at 08:12

Henrik Schumacher · Accepted Answer · 2018-08-16T08:07:52.697

8

Since you already use Cross in a way that it's not meant to be used, you can also redefine it and assign a meaning to it when it has only a single argument:

Unprotect[Cross]; 
Cross[x_] := x;

A bit less severe: Define your own function.

cross[x__] := Cross[x];
cross[x_] := x;

edited Aug 16 '18 at 08:07

answered Aug 16 '18 at 08:02

Henrik Schumacher

106,770
7
179
309

Fred Simons · Answer 3 · 2018-08-17T06:51:39.187

6

You might define your own function cross, that calls Cross when the number of arguments is larger than 1:

cross=If[Length[{##}]>1, Cross[##], #]&;

edited Aug 17 '18 at 06:51

answered Aug 16 '18 at 08:01

Fred Simons

10,181
18
49

Thanks. Is there any method to check the number of arguments instead of using your trick with Length[{...}]? – Friendly Ghost Aug 16 '18 at 08:03

score 5 · Answer 4 · answered Aug 16 '18 at 08:03

5

An alternative solution without defining new functions:

PrimeFactorization[x_] :=

 Superscript @@@ FactorInteger[x] /. y_ /; Length@y < 0 -> Cross @@ y

answered Aug 16 '18 at 08:03

Fraccalo

6,057
13
28

score 5 · Answer 5 · answered Aug 16 '18 at 11:38

5

For displaying purposes you can also use:

Times @@ Defer@*Power @@@ FactorInteger[10!]

CenterDot @@ Superscript @@@ FactorInteger[10!]

Inactive[Times] @@ Superscript @@@ FactorInteger[10!]

answered Aug 16 '18 at 11:38

chyanog

15,542
3
40
78

(+1) This does not resolve the issue with numbers that are a power if a prime though. – Henrik Schumacher Aug 16 '18 at 16:59

kglr · Answer 6 · 2018-08-17T07:46:06.927

2

You can use Block in two ways:

temporarily re-define Cross so that Cross[t_] := t:

PrimeFactorization[x_] :=  Block[{Cross}, Cross[t_] := t;
   Cross @@ Superscript @@@ FactorInteger @ x];

PrimeFactorization /@ {211, 222, 223} // TeXForm

$\left\{211^1,2^1\times 3^1\times 37^1,223^1\right\}$

temporarily define Sequence as Cross:

PrimeFactorization2[x_] := Block[{Sequence = Cross},
    ## & @@ Superscript @@@ FactorInteger @ x];

PrimeFactorization2 /@ {211, 222, 223} // TeXForm

$\left\{211^1,2^1\times 3^1\times 37^1,223^1\right\}$

edited Aug 17 '18 at 07:46

answered Aug 17 '18 at 07:24

kglr

394,356
18
477
896

I already up voted this answer! The proof (click). – Friendly Ghost Aug 17 '18 at 13:23

How to avoid applying Cross to a single argument?

6 Answers6

Linked