How to insert elements at different locations of a given list

Question

Say a list is given as

list = {a, b, c, d, r, m, n};

Suppose I want to insert 2 and 3 at position 3 and 7, respectively.

Insert[list, 2, 3] puts 2 at position 3, but Insert[list, {{2, 3}, {3, 7}}] does nothing.

How is it possible?

Dirty trick: Block[{k = 0}, Insert[{a, b, c, d, r, m, n}, Unevaluated[{2, 3}[[++k]]], {{3}, {7}}]] — J. M.'s missing motivation, Sep 27 '18 at 13:02
@J.M. Wow, that one is really dirty. I had to read it several times to understand it half way at least... — Henrik Schumacher, Sep 27 '18 at 14:48
@Henrik, I didn't want to post it as an answer lest it be thought of as an endorsement. ;D — J. M.'s missing motivation, Sep 27 '18 at 14:52
related: Looking for a way to insert multiple elements into multiple positions simultaneously in a list — user1066, Sep 28 '18 at 00:07

Αλέξανδρος Ζεγγ · Answer 1 · 2018-09-27T14:02:33.440

7

How about this

myInsert[list_, valuePosList_] := Fold[Insert[#, Sequence @@ #2] &, 
                                       list, 
                                       SortBy[valuePosList, -Last[#] &]
                                      ]

myInsert[list, {{2, 3}, {3, 7}}]

{a, b, 2, c, d, r, m, 3, n}

edited Sep 27 '18 at 14:02

answered Sep 27 '18 at 13:50

Αλέξανδρος Ζεγγ

9,783
3
20
41

score 6 · Accepted Answer · answered Sep 27 '18 at 14:50

6

Look what I found after spelunking:

GroupTheory`PermutationGroups`Private`FoldInsert[
 {a, b, c, d, r, m, n},
 {2, 3}, {3, 7}
 ]

{a, b, 2, c, d, r, 3, m, n}

Well, it is not entirely correct for it does not revert the order of insertion... =/

answered Sep 27 '18 at 14:50

Henrik Schumacher

106,770
7
179
309

Wow! $\phantom{}$ – J. M.'s missing motivation Sep 27 '18 at 14:53
1

I wonder if this package has similar functions. – Αλέξανδρος Ζεγγ Sep 27 '18 at 15:16
@ΑλέξανδροςΖεγγ That package appears to be very new. Good to know! (... although I won't find it applicable to my own work...) – Henrik Schumacher Sep 27 '18 at 15:26
@HenrikSchumacher Yes, it is accompanied with a book published just about two months ago. – Αλέξανδρος Ζεγγ Sep 27 '18 at 16:20

score 3 · Answer 3 · answered Sep 27 '18 at 15:55

3

insertList[list_, valuePosList_] := ReplacePart[
  list,
  Apply[
   Rule[#2, Sequence[#1, list[[#2]]]] &,
   valuePosList
   , {1}
   ]
  ]

Mathematica graphics

answered Sep 27 '18 at 15:55

rhermans

36,518
4
57
149

How to insert elements at different locations of a given list

3 Answers3