Fill to the left of the y-axis only

Question

I have the following code that produces a plot of a Normal distribution:

Plot[Table[PDF[NormalDistribution[μ, 3], x], {μ, {4}}] // Evaluate, {x, -15, 15}, 
 Filling -> None, Axes -> {True, True}, Ticks -> None, 
 PlotStyle -> {RGBColor[0.368417, 0.506779, 0.709798],
  RGBColor[0.880722, 0.611041, 0.142051]}]

How do I fill to the left of the y-axis only?

OkkesDulgerci · Answer 1 · 2018-10-26T13:24:18.573

4

How about this:

 f[x_] := PDF[NormalDistribution[4, 3], x]

Show[Plot[f[x], {x, -15, 15}, Ticks -> None, 
  PlotStyle -> {RGBColor[0.880722, 0.611041, 0.142051]}], 
 Plot[f[x], {x, -15, 0}, 
  PlotStyle -> {RGBColor[0.880722, 0.611041, 0.142051]}, 
  PlotRange -> All, Filling -> Axis]]

edited Oct 26 '18 at 13:24

answered Oct 26 '18 at 12:47

OkkesDulgerci

10,716
1
19
38

kglr · Answer 2 · 2018-10-26T15:47:41.820

ConditionalExpression combined with the option Filling:

Plot[{PDF[NormalDistribution[4, 3], x], ConditionalExpression[0, x <= 0]}, {x, -15, 15}, 
  Ticks -> None, 
  PlotStyle -> {RGBColor[0.880722, 0.611041, 0.142051], None}, 
  Filling -> {1 -> {2}}]

Plot[Evaluate @ Append[Table[PDF[NormalDistribution[μ, 3], x], {μ, {3, 4, 5}}],
   ConditionalExpression[0, x <= 0]] , {x, -15, 15},  
 Filling -> {1 -> {4}, 2 -> {4}, 3 -> {4}},
 Ticks -> None, 
 PlotStyle -> Append[ColorData[97] /@ {1, 2, 3}, None], 
 PlotLegends -> ("μ = " <> # & /@ {"3", "4", "5"})]

Fill to the left of the y-axis only

2 Answers2