Cat catch mouse , application of differentials equations

Question

Can anyone help me with this:

We have a room 4 metres deep and 4 metres wide. In the far right corner is a mousehole. The cat starts in the bottom left corner, and the mouse starts in the top left corner i.e. cat starts at (0,0) and mouse at (0,4), and the mouse hole is at (4,4).

The cat starts to chase the mouse and always runs directly at the mouse. The mouse runs straight for the hole i.e. along the top wall from (0,4) towards (4,4).

The cat has a constant speed, so too does the mouse. Cat speed is 2x faster than mouse .

Questions: Will cat catch the mouse, before mouse get away ?

I will ilustrate solving step by step manualy

1. $y=y(x) $ equations of curve (cat route way )

In moment $x_0$ cat made pass way : $$l(x_0)=\int_{0}^{x_0} \sqrt{1+(y'(s))^2} ds. $$

Mouse way is on tanget's of curve $y=y(x)$ , equation of that tanget is $$p(x)-y(x_0)=y'(x_0)(x-x_0).$$

So coordinates of mouse are $$\left(4,y(x_0)+y'(x_0)(4-x_0)\right),$$ from it we get $$\int_{0}^{x} \sqrt{1+(y'(s))^2} ds=2\left(y(x)+y'(x)(4-x)\right).$$ $$\sqrt{1+(y'(x))^2}=2(4-x)y''(x). $$

We need solve Cauchy problem

$$\left\{\begin{array}{rcl} 2\sqrt{1+(y'(x))^2}&=&2(4-x)y''(x), \\ y(0)&=&0,\\ y'(0)&=&0 \end{array}\right.$$

When we solve it we get

$$y(x)=\frac{1}{6} \left(-\sqrt{4-x} x-8 \sqrt{4-x}+16\right)$$,$$y(x)=\frac{1}{6} (-16 + 8\sqrt{4 - x} + \sqrt{4 - x} x).$$

My question here for Mathematica is next:

Have anyone idea how to make manipulate that i see on graph cat-mouse moving, so with that manipulate I can see the moment and when cat catch mouse etc.

I wrote for my Student research project this and now i need as much as can to involve here Mathematica (so give some idea if you have for plotting , manipulate plot etc) .

Answer 1

This case is valid for the cat running twice as fast as the mouse. The equation for y

y[x_] = 1/6 (-Sqrt[4 - x] x - 8 Sqrt[4 - x] + 16)

Call the mouse velocity 1

v = 1

Find x as a function of t from

txeq = v t == y[x] + y'[x] (4 - x) // Simplify;

xsol = Solve[%, x] // Flatten // Simplify;

{x /. xsol[[1]], x /. xsol[[2]], x /. xsol[[3]]} /. t -> .1
(*{17.9 - 7.51202 I, 0.199978 - 7.77156*10^-16 I, 17.9 + 7.51202 I}*)

The second one is the Real one.

x[t_] = x /. xsol[[2]] // FullSimplify

Now find the time the cat hits the wall at x = 4

Solve[txeq, t] // Flatten
(*{t -> (-x^2 + 20 x + 32 Sqrt[4 - x] - 64)/(12 Sqrt[4 - x])}*)

tf = Limit[t /. %, x -> 4]
(*8/3*)

Check

x[tf] // N[#, 20] &
(*4.0000000000000000000 + 0.*10^-20 I*)

ok

gifs = Table[
   ParametricPlot[{{x[t], y[x[t]] // Chop}, {4, v t}}, {t, .001, ti}, 
    PlotRange -> {{0, 4}, {0, 4}}, PlotStyle -> Thickness[.02]], {ti, 
    0, tf, tf/50}];
ListAnimate[%]

Update While no longer applying to the original question, I will leave the results here as it is valid for the case where the cat runs with the same speed as the mouse.

The equation for y[x]

DSolve[{2 Sqrt[1 + y'[x]^2] == 2 (4 - x) y''[x], y[0] == 0, 
   y'[0] == 0}, y[x], x] // Flatten
(*{y[x] -> 1/16 (4 - x)^2 - 2 Log[4 - x] - 1 + 2 Log[4]}*)

y[x_] = y[x] /. %;

Again, set the mouse velocity to be 1

v = 1;

The mouse y position is v t and the cat is running toward it, so get x as a function of t from:

txeq = v t == y[x] + y'[x] (4 - x) // Simplify
(*16 t + x^2 + 32 Log[4 - x] == 8 (x + Log[256])*)

xsol = Solve[txeq, x] // Flatten // Simplify;

Lots of conditional answers. After considerable experimentation to find the real solution, I get.

x[t_] = x /. xsol[[7]] /. C[1] -> 0 // FullSimplify[#, t >= 0] &
(*4 - 4 Sqrt[ProductLog[E^(1 - t)]]*)

The total time is the time the mouse gets to the hole since in this case the cat never catches up.

v tf == 4

tf = 4

The x distance the cat gets to when the mouse gets to the hole.

x[tf] // N
(*3.12842*)

gifs = Table[
   ParametricPlot[{{x[t], y[x[t]]}, {4, v t}}, {t, .0001, ti}, 
    PlotRange -> {{0, 4.1}, {0, 4.1}}, PlotStyle -> Thickness[.02], 
    Epilog -> {PointSize[.02], Point[{4, 4}]}], {ti, 0, tf, tf/50}];
ListAnimate[%]