Why cannot I label a date point using TimelinePlot with Manipulate?

Question

I have tried to simplify this issue as much as I can at the moment: it looks like a bug to me but perhaps I've missed something obvious.

I am trying to build an interactive scheduler using TimelinePlot and I find that the following code reports that I've tried to plot an invalid dataset:

Manipulate[Column@{DatePlus[{2019, 1, 15}, sdate],
TimelinePlot[{{Labeled[{2011, 1, 1}, "hello"], {2012, 1, 1}, {2013, 1, 1}}, 
    {Labeled[Interval[{{2011, 3, 1}, {2012, 7, 7}}], mylabel], 
     Interval[{{2012, 9, 12}, {2013, 12, 21}}]}, {Labeled[
     Interval[{DatePlus[{2011, 3, 1}, sdate], 
     DatePlus[{2012, 7, 7}, sdate]}], "Moving interval"], 
     Labeled[Interval[{{2012, 9, 12}, {2013, 12, 21}}], "Range"]}}]}, 
  {sdate, 0, 200, 1}, 
  {mylabel, {"la", "lb", "lc"}}]

Mathematica graphics

but this works fine

Manipulate[Column@{DatePlus[{2019, 1, 15}, sdate],
TimelinePlot[{{{2011, 1, 1}, {2012, 1, 1}, {2013, 1, 1}}, 
{Labeled[
   Interval[{{2011, 3, 1}, {2012, 7, 7}}], mylabel], 
   Interval[{{2012, 9, 12}, {2013, 12, 21}}]}, 
{Labeled[
   Interval[{DatePlus[{2011, 3, 1}, sdate], 
     DatePlus[{2012, 7, 7}, sdate]}], "Moving interval"], 
   Labeled[Interval[{{2012, 9, 12}, {2013, 12, 21}}], 
   "Range"]}}]}, {sdate, 0, 200, 1}, 
{mylabel, {"la", "lb", "lc"}}]

Mathematica graphics

as well as this:

With[{sdate = 1, mylabel = "foo"},
 Column@{DatePlus[{2019, 1, 15}, sdate],
 TimelinePlot[{{Labeled[{2011, 1, 1}, "hello"], {2012, 1, 1}, {2013,
    1, 1}}, {Labeled[Interval[{{2011, 3, 1}, {2012, 7, 7}}], 
   mylabel], 
  Interval[{{2012, 9, 12}, {2013, 12, 21}}]}, {Labeled[
   Interval[{DatePlus[{2011, 3, 1}, sdate], 
     DatePlus[{2012, 7, 7}, sdate]}], "Moving interval"], 
  Labeled[Interval[{{2012, 9, 12}, {2013, 12, 21}}], "Range"]}}]}]

Mathematica graphics

kglr · Accepted Answer · 2018-12-21T13:31:45.980

1

Looks like a bug. Two smaller examples exhibiting two aspects of the issue:

(1) TimelinePlot[{{Labeled[{2011, 3, 1}, "Label"]}}] works as expected but Manipulate[TimelinePlot[{{Labeled[{2011, 3, 1}, "Label"]}}], {sdate, 0, 200, 1}] gives an error.

(2) Although TimelinePlot[{{{2011, 3, 1}, Interval[{{2011, 3, 1}, DatePlus[{2011, 3, 1}, 100]}]}}] works fine, inside Manipulate it gives an error message. In general, if any element of datai in TimeLinePlot[{data1, ..., datan}] is a date list ({y,m,d,...}) without wrappers all elements of datai should be date lists without wrappers.

A work-around: Wrap the date lists with DateObject (or DateList or AbsoluteTime), that is, use

{Labeled[DateObject@{2011, 1, 1}, "hello"], DateObject@{2012, 1, 1}, DateObject@{2013, 1, 1}}

in the first sublist of your input data to get

edited Dec 21 '18 at 13:31

answered Dec 21 '18 at 10:58

kglr

394,356
18
477
896

yes, that seems to fix it thanks – fairflow Dec 21 '18 at 13:42
just waiting to see if it is confirmed as a bug and if that's the best workaround. – fairflow Dec 21 '18 at 13:43
well, I haven't asked via the official route if it's a bug; it could be called a design choice but I prefer to mark it as a bug. Only I'm not quite sure how to do that, I'll have to find out what the standard bug headers are... – fairflow Jan 02 '19 at 17:29
@fairflow, please see How to report a bug in Mathematica. – kglr Jan 03 '19 at 23:35
yes @kglr thanks for the prompt; but actually I wanted to know how to add a bug tag to a question and the advice is not just to add the tag bug but to use the "standard bug headers" instead and I didn't know what that meant. – fairflow Jan 05 '19 at 10:11

Why cannot I label a date point using TimelinePlot with Manipulate?

1 Answers1