How to remove the item that is repeated?

Question

If i have a

list={m,n,p,q,q,r,l,l}

how can i remove the repeated item with pattern matching so i would have

modifiedlist={m,n,p,r}?

Closely related: https://mathematica.stackexchange.com/q/40317/5478 — Kuba, Jan 23 '19 at 12:39
Also related https://mathematica.stackexchange.com/q/107483/106 — user1066, Jan 23 '19 at 13:20

kglr · Accepted Answer · 2019-01-23T14:53:27.150

7

Keys@Select[Counts[list], # == 1 &]

{m, n, p, r}

Also:

Select[list, Count[list, #] == 1 &]
Select[list, Counts[list][#] == 1 &]
Flatten[Cases[Split[Sort[list]], {_}]]
Flatten[DeleteCases[Split[Sort[list]], {_, __}]]
Flatten[Select[Split[Sort[list]], Length@# == 1 &]]
SequenceReplace[list, {OrderlessPatternSequence[Repeated[b_, {2, Infinity}], a_]} :> a]

edited Jan 23 '19 at 14:53

answered Jan 23 '19 at 12:23

kglr

394,356
18
477
896

very nice i added {m,n,p,q,q,r,l,l} /. a_List :> Select[a, Count[a, #] == 1 &] – user49047 Jan 23 '19 at 12:26
@user49047, Select[a, Count[a, #] == 1 &] gives you the result directly; you don't need to use ReplaceAll. – kglr Jan 23 '19 at 12:30
The method using Counts is probably the best way, since you only have to traverse the whole list once. – Sjoerd Smit Jan 23 '19 at 12:41
@SjoerdSmit, excellent point. – kglr Jan 23 '19 at 12:43

score 6 · Answer 2 · answered Jan 23 '19 at 12:46

6

First /@ Select[Tally@list, Last@# == 1 &]

{m, n, p, r}

or

First /@ Cases[Tally@list, {_, 1}]

{m, n, p, r}

answered Jan 23 '19 at 12:46

Jerry

2,459
9
15

1

Cases[] seems to be fastest so far on large lists. Cases[Tally@list, {_, 1}][[All, 1]] is about 10% faster on unpacked arrays, slightly slower on packed arrays. – Michael E2 Jan 23 '19 at 12:58

How to remove the item that is repeated?

2 Answers2