Convert a list of lists into a list of rules

Question

I have some trouble converting an imported list looking like this:

{{a, b}, {c, d}, {e, f}}

into a list of rules looking like this:

{{a -> b}, {c -> d}, {e -> f}}

It is a list of lists of rules. But anyway: List@*Rule@@@... — Kuba, Mar 01 '19 at 19:24
Thx. So like this? data = {{a,b},{c,d},{e,f}} data@*Rule@@@ ? — user3483676, Mar 01 '19 at 19:35
https://mathematica.stackexchange.com/q/88429 is a very similar question — m_goldberg, Mar 02 '19 at 01:32

m_goldberg · Accepted Answer · 2019-03-02T01:58:37.463

10

Why not

list = {{a, b}, {c, d}, {e, f}};
Rule @@@ list

{a -> b, c -> d, e -> f}

This will work as well as

{{a -> b}, {c -> d}, {e -> f}}

in just about every situation where you are likely need a list of rules.

Of course, if you must have the particular form that you show, there is

{#1 -> #2} & @@@ list

and

{#[[1]] -> #[[2]]} & /@ list

and

List @* Rule @@@ list

and

List @@@ Rule @@@ list

edited Mar 02 '19 at 01:58

answered Mar 02 '19 at 00:49

m_goldberg

score 4 · Answer 2 · answered Mar 01 '19 at 19:33

4

Why not:

list1 = {{a,b},{c,d},{e,f}};
list2 = Table[{list[[i, 1]] -> list[[i, 2]]}, {i, 1, Length[list]}]

prints out

{{a -> b}, {c -> d}, {e -> f}}

answered Mar 01 '19 at 19:33

Valacar

score 1 · Answer 3 · answered Jan 31 '24 at 00:27

1

list = {{a, b}, {c, d}, {e, f}};

Using MapApply (new in 13.1)

MapApply[List @* Rule] @ list

{{a -> b}, {c -> d}, {e -> f}}

answered Jan 31 '24 at 00:27

eldo

score 1 · Answer 4 · answered Jan 31 '24 at 02:25

1

list = {{a, b}, {c, d}, {e, f}};

Using Cases;

Cases[list, v_ :> List@*Rule @@ v]
({{a -> b}, {c -> d}, {e -> f}})

Or using MapThread:

MapThread[List@Rule[#1, #2] &, Thread@#] &@list
({{a -> b}, {c -> d}, {e -> f}})

answered Jan 31 '24 at 02:25

E. Chan-López

4 Answers4