Find list position and mapping list

Question

Sorry, my English is not very good.

I have two lists:

tt = {197, 173, 23, 151, 69, 90, 12, 192, 158, 32, 6, 147, 99, 
  199, 131, 10, 59, 144, 141, 24, 178, 58, 106, 25, 155, 153} 

ii = {{46, 154}, {93, 158}, {125, 214}, {160, 112}, {184, 200}, {203, 
  137}, {230, 266}, {271, 128}, {317, 153}, {362, 251}, {369, 
  252}, {385, 136}, {424, 195}, {503, 139}, {538, 181}, {582, 
  268}, {602, 227}, {621, 108}, {660, 147}, {695, 245}, {739, 
  132}, {766, 242}, {786, 161}, {822, 239}, {857, 128}, {904, 171}}

I can find elements of list tt that are > 150:

Select[tt, # > 150 &]

{197, 173, 151, 192, 158, 199, 178, 155, 153}

Q1 : How can I find the positions of these elements in tt?

I want find answer, such as:

location = {1,2,4,8,9,14,21,25,26}
or location = {1,1,0,1,0,0,0,1,1,0,0,0,0,1,0,0,0,0,0,0,1,0,0,0,1,1}

How can I mapping to the same location to ii list which get data?

You want Position and Extract. – Xerxes Feb 21 '13 at 06:55 — Xerxes, Feb 21 '13 at 06:55
@Nasser thanks you for offer the good information !! – Darren Lee Feb 21 '13 at 11:17 — Darren Lee, Feb 21 '13 at 11:17

Mr.Wizard · Accepted Answer · 2013-02-21T08:45:22.120

Most directly:

Pick[ii, tt, x_ /; x > 150]

{{46, 154}, {93, 158}, {160, 112}, {271, 128}, {317, 153},
 {503, 139}, {739, 132}, {857, 128}, {904, 171}}

Or slightly more efficiently:

Pick[ii, Thread[tt > 150]]

{{46, 154}, {93, 158}, {160, 112}, {271, 128}, {317, 153},
 {503, 139}, {739, 132}, {857, 128}, {904, 171}}

Some other things to observe:

p1 = Join @@ Position[tt, x_ /; x > 150]

{1, 2, 4, 8, 9, 14, 21, 25, 26}

mask = Boole @ Thread[tt > 150]

{1, 1, 0, 1, 0, 0, 0, 1, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 1, 1}

ii[[p1]]

{{46, 154}, {93, 158}, {160, 112}, {271, 128}, {317, 153},
 {503, 139}, {739, 132}, {857, 128}, {904, 171}}

Pick[ii, mask, 1]

{{46, 154}, {93, 158}, {160, 112}, {271, 128}, {317, 153},
 {503, 139}, {739, 132}, {857, 128}, {904, 171}}

Also:

ii ~Extract~ Position[tt, x_ /; x > 150]

{{46, 154}, {93, 158}, {160, 112}, {271, 128}, {317, 153},
 {503, 139}, {739, 132}, {857, 128}, {904, 171}}

@user5990 I'm glad you found it useful, and thanks for the Accept. If performance is a prime concern in your application be sure to see the SparseArray method in kguler's post and look at the timings here which relate to a similar problem. — Mr.Wizard, Feb 21 '13 at 11:25

user1066 · Answer 2 · 2013-02-21T08:41:56.280

7

Do you want something like this?

Pick[ii, # >= 150 & /@ tt]

=> {{46, 154}, {93, 158}, {160, 112}, {271, 128}, {317, 153}, {503, 139}, {739, 132}, {857, 128}, {904, 171}}

or

location = Boole[# >= 150] & /@ tt

=> {1, 1, 0, 1, 0, 0, 0, 1, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 1, 1}

and

Pick[ii, location, 1]

edited Feb 21 '13 at 08:41

answered Feb 21 '13 at 08:20

user1066

17,923
3
31
49

We are thinking along the same lines. (+1) – Mr.Wizard Feb 21 '13 at 08:46
Thanks for, It the great solution :) – Darren Lee Feb 21 '13 at 11:17

score 5 · Answer 3 · edited Feb 21 '13 at 11:21

5

 ttpos=MapIndexed[If[# >= 150, First@#2, ## &[]] &, tt]

or

 ttpos=Select[Range[Length[tt]], tt[[#]] >= 150 &]
 (* {1, 2, 4, 8, 9, 14, 21, 25, 26} *)

or

 UnitStep[tt - 150]
 (* {1, 1, 0, 1, 0, 0, 0, 1, 1, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 1, 1}*)

 Range[Length[tt]] UnitStep[tt - 150] /. (0) -> Sequence[]

or

 SparseArray[UnitStep[tt - 150]]["AdjacencyLists"]
 (* {1, 2, 4, 8, 9, 14, 21, 25, 26} *)

For the corresponding elements in ii:

 ii[[ttpos]]
 (* {{46, 154}, {93, 158}, {160, 112}, {271, 128}, {317, 153},
   {503,  139}, {739, 132}, {857, 128}, {904, 171}} *)

edited Feb 21 '13 at 11:21

Mr.Wizard

271,378
34
587
1,371

answered Feb 21 '13 at 09:42

kglr

394,356
18
477
896

I wondered who would post the numeric solution. +1 :-) – Mr.Wizard Feb 21 '13 at 10:44
@Mr.Wizard, was surprised to see that you did not post your trademark;) – kglr Feb 21 '13 at 11:05
You mean "NonzeroPositions"/"AdjacencyLists" e.g. (1), (2), (3), (4), (5), (6)? Do I need to hit even a beginner's question with that bludgeon? :^) – Mr.Wizard Feb 21 '13 at 11:15
I see that while I was finding those links you hit it for me. :o) – Mr.Wizard Feb 21 '13 at 11:16
@Mr.Wizard, (that too), but I meant ##&[]. – kglr Feb 21 '13 at 11:18
Hi, @kglr. I am surprised that I didn't know Mr.Wizard's trademark>_< . How is ##&[] related to this question? – matheorem Oct 24 '16 at 12:14
@Mr.Wizard There seems a problem with SparseArray[UnitStep[tt - 150]], it is equivalent to tt>=150, not tt>150. I can't figure out how to fix this. – matheorem Oct 24 '16 at 13:50
@matheorem (1) see http://mathematica.stackexchange.com/a/3705/121; I don't think I would call it a signature myself but I do use it fairly often I suppose. (2) SparseArray[1 - UnitStep[150 - tt]] or SparseArray[UnitStep[150 - tt], Automatic, 1]? – Mr.Wizard Oct 24 '16 at 20:24
@Mr.Wizard Thank you so much, Mr. Wizard! Learned a lot : ) – matheorem Oct 27 '16 at 15:19

score 3 · Answer 4 · answered Feb 21 '13 at 07:03

Try like this,

for positions

  positions = Map[
                  (
                    If[
                        (# > 150),
                        (Position[tt, #]),
                        ("")
                    ]   
                ) &,
                tt
                ];
    Cases[Flatten[positions], Except[""]]

for binary values:

  Map[
(
    If[
            (# > 150),
            (1),
            (0)
        ]   
) &,
tt
]

Find list position and mapping list

4 Answers4

Linked