How can I animate the following curve?
ParametricPlot3D[
{Cos[Sqrt[2] t](3 + Cos[t]), Sin[Sqrt[2] t] (3 + Cos[t]), Sin[t]},
{t, 0, 50}
]
Can I also remove the coordinate box?
Asked
Active
Viewed 692 times
8
-
Sorry, I meant to generate the line as in this video https://www.youtube.com/watch?v=YfKxzKM-MNc – user21210 Jun 16 '19 at 05:44
2 Answers
8
I would use Manipulate as it is just like Animate but more flexible.
Manipulate[
Module[{t},
ParametricPlot3D[{Cos[Sqrt[2] t] (3 + Cos[t]),
Sin[Sqrt[2] t] (3 + Cos[t]), Sin[t]},
{t, 0, maxTime},
ImageSize -> 300,
PlotRange -> {{-4, 4}, {-4, 4}, {-1, 1}},
PlotStyle -> Red]
]
,
{{maxTime, 1, "time"}, 1, 50, 0.01, Appearance -> "Labeled"},
TrackedSymbols :> {maxTime}
]
To removed the box and the axis, look at options Boxed -> False and Axes -> False
In Manipulate, you decide which are the control variables in your expression. For each one, you add a control variable definition in the body of the Manipulate. In this case, there is only one control variable.
Nasser
- 143,286
- 11
- 154
- 359
-
-
@AbdelRahmanAl-Amrat Yes. Open the Manipulate control (click on the small + thing on the right side of the slider) and click on the
>button to play it. – Nasser Jun 16 '19 at 05:57
2
Animate[ParametricPlot3D[{Cos[Sqrt[2]t], Sin[Sqrt[2]t] (3 + Cos[t]), Sin[t]}, {t, 0, tmax},
PlotRangePadding -> Scaled[.1],
PlotRange -> {{-1.1, 1.1}, {-2 Pi, 2 Pi}, {-1.1, 1.1}}] /.
Line -> ({CapForm[None], FaceForm[Opacity[.5, Blue], Yellow], Tube[#, .1]} &),
{tmax, 1, 50, .01},
AnimationRunning -> False]
kglr
- 394,356
- 18
- 477
- 896