Picking elements from a list

Question

That's must be a very trivial question. Suppose we have the simple list

data = {{-1, 0}, {0.2, 0.4}, {4, 0}, {0.3, 0}, {0.2, -0.4}};

Then, is there a quick and elegant way to pick the element with non-zero and positive y value? In this example, we should get {0.2, 0.4}.

Select[data, Positive[#[[2]]]&] – Jason B. Jun 27 '19 at 14:36 — Jason B., Jun 27 '19 at 14:36
Alternatively, data//Pick[#, Sign[#[[All,2]]],1]& – user1066 Jun 27 '19 at 15:50 — user1066, Jun 27 '19 at 15:50
A minor variation: Select[Positive@*Last][data] – Syed Feb 04 '24 at 02:07 — Syed, Feb 04 '24 at 02:07

kickert · Accepted Answer · 2019-06-27T15:16:37.383

5

Select is a good option here. Jason has shown in the comments how to use the Positive function. If you want a bit more flexibility for future usage, you can use a standard greater than operator.

data = {{-1, 0}, {0.2, 0.4}, {4, 0}, {0.3, 0}, {0.2, -0.4}};    
positivedata=Select[data, #[[2]] > 0 &]

edited Jun 27 '19 at 15:16

answered Jun 27 '19 at 14:51

kickert

1,820
8
22

score 4 · Answer 2 · answered Jun 28 '19 at 00:41

4

You can also use Cases:

Cases[{_, _?Positive}] @ data

{{0.2, 0.4}}

answered Jun 28 '19 at 00:41

kglr

394,356
18
477
896

score 2 · Answer 3 · answered Feb 04 '24 at 00:14

data = {{-1, 0}, {0.2, 0.4}, {4, 0}, {0.3, 0}, {0.2, -0.4}};

Pre-define pattern for better comparability

p = {_, x_} /; x <= 0;

Using SequenceSplit (new in 11.3)

First @ SequenceSplit[data, {p}]

Using ReplaceAt (new in 13.1)

ReplaceAt[data, _ :> Nothing, Position[p] @ data]

Using ReplaceAll

data /. p :> Nothing

Using Delete

Delete[Position[p] @ data] @ data

E. Chan-López · Answer 4 · 2024-02-04T01:31:44.413

1

data = {{-1, 0}, {0.2, 0.4}, {4, 0}, {0.3, 0}, {0.2, -0.4}, {-1, -1}};

Using Pick:

Pick[#, Element[#, PositiveReals] & /@ #] &@data
({{0.2, 0.4}})

Or using DeleteCases:

DeleteCases[data, s_ /; ! MatchQ[Sign@s, {1 ..}]]
({{0.2, 0.4}})

An alternative using Pick:

Pick[#, MatchQ[Thread[{##} > 0], {True ..}] & @@@ #] &@data
({{0.2, 0.4}})

edited Feb 04 '24 at 01:31

answered Feb 04 '24 at 00:52

E. Chan-López

23,117
3
21
44

1

I know it works for this case but if data have {-1,-1}, then your approach will not work. – OkkesDulgerci Feb 04 '24 at 01:07
Thanks for the observation, @OkkesDulgerci! See the update, please. :-) – E. Chan-López Feb 04 '24 at 01:18

score 1 · Answer 5 · answered Feb 04 '24 at 08:34

1

A Reap/Sow variant:

Reap[Sow @@@ data, _?(# > 0 &), {#2[[1]], #1} &][[2]]

answered Feb 04 '24 at 08:34

ubpdqn

60,617
3
59
148

score 1 · Answer 6 · answered Feb 04 '24 at 11:25

data = {{-1, 0}, {0.2, 0.4}, {4, 0}, {0.3, 0}, {0.2, -0.4}};

Select[0 < ArcTan @@ # < π &][data]

{{0.2, 0.4}}

Visualization:

pts = RandomReal[{-1, 1}, {400, 2}];
sel = Select[0 < ArcTan @@ # < π &][pts];
unsel = Complement[pts, sel];
ListPlot[{sel, unsel}, PlotStyle -> {Red, Blue}]

Picking elements from a list

6 Answers6

Linked