Move the outer key inward in an association

Question

I have a list that looks like:

{15000001-><|"Loss" -> 2.85396*10^8, "Exposure" -> 6.61052*10^10|>,
 15000002 -> <|"Loss" -> 1.25297*10^8, "Exposure" -> 1.57863*10^11|>,
 15000003 -> <|"Loss" -> 2.05979*10^8, "Exposure" -> 6.88024*10^10|>}

I want to wind up with this:

{<|"Event"->15000001,"Loss" -> 2.85396*10^8, "Exposure" -> 6.61052*10^10|>,
 <|"Event"->15000002,"Loss" -> 1.25297*10^8, "Exposure" -> 1.57863*10^11|>,
 <|"Event"->15000003,"Loss" -> 2.05979*10^8, "Exposure" -> 6.88024*10^10|>}

I tried making two lists, one with Keys and one with Values and putting them together, but I couldn't quite get that to work. I'd appreciate any suggestions.

Lukas Lang · Answer 1 · 2019-07-31T08:50:55.977

14

Here's an approach using @@@ (Apply at level {1}):

Prepend[#2, "Event" -> #] & @@@ lst
(* {
    <|"Event" -> 15000001, "Loss" -> 2.85396*10^8, "Exposure" -> 6.61052*10^10|>, 
    <|"Event" -> 15000002, "Loss" -> 1.25297*10^8, "Exposure" -> 1.57863*10^11|>,
    <|"Event" -> 15000003, "Loss" -> 2.05979*10^8, "Exposure" -> 6.88024*10^10|>
   } *)

As noted by @WReach in the comments, we can also use the (undocumented?) fact that associations behave as if they had the Flat attribute (meaning that e.g. <|a->1,<|b->2|>|> evaluates to <|a->1,b->2|>):

<| "Event" -> #, #2 |> & @@@ lst
(* same output *)

edited Jul 31 '19 at 08:50

answered Jul 29 '19 at 09:16

Lukas Lang

33,963
1
51
97

4

+1. Also: <| "Event" -> #, #2 |> & @@@ lst – WReach Jul 30 '19 at 04:33
@WReach Thanks! I've added your solution as an alternative to the answer – Lukas Lang Jul 31 '19 at 08:51

kglr · Accepted Answer · 2019-07-29T00:56:21.987

Join @@ KeyValueMap[Prepend[#2, "Event" -> #]&] /@ (Association /@ lst)

{<|"Event" -> 15000001, "Loss" -> 2.85396*10^8, "Exposure" -> 6.61052*10^10|>,
<|"Event" -> 15000002, "Loss" -> 1.25297*10^8, "Exposure" -> 1.57863*10^11|>,
<|"Event" -> 15000003, "Loss" -> 2.05979*10^8, "Exposure" -> 6.88024*10^10|>}

Alternatively, use Replace:

Replace[lst, HoldPattern[a_ -> <|b___|>] :> <|"Event" -> a, b|>, All]

same result

score 3 · Answer 3 · answered Jul 29 '19 at 02:19

Using keyPush by @alancalvitti

keyPush[newKey_][<|k_ -> as_Association|>] := Prepend[newKey -> k][as];

keyPush["Event"][Association@#] & /@ lst

{<|"Event" -> 15000001, "Loss" -> 2.85396*10^8, "Exposure" -> 6.61052*10^10|>, <|"Event" -> 15000002, "Loss" -> 1.25297*10^8, "Exposure" -> 1.57863*10^11|>, <|"Event" -> 15000003, "Loss" -> 2.05979*10^8, "Exposure" -> 6.88024*10^10|>}

Move the outer key inward in an association

3 Answers3