How to save matrices from each iteration of i?

Question

I am trying to get the transformation matrices from DH parameter table and would like to save each matrix (Ai) getting after each iteration of i. How can I do that?

DH = {{0, T1, 0, 0}, {0, T2, L1, Pi/2}, {0, T3, L2, 0}, {0, 0, L3, 0}} 
For[i = 1, i <= 4, i++, 
A = {{Cos[DH[[i, 2]]], -Sin[DH[[i, 2]]], 0, DH[[i, 3]]}, 
{Sin[DH[[i, 2]]] Cos[DH[[i, 4]]], Cos[DH[[i, 2]]] Cos[DH[[i, 4]]],Sin[DH[[i, 4]]], -Sin[DH[[i, 4]]] DH[[i, 1]]}, 
 {Sin[DH[[i, 2]]] Sin[DH[[i, 4]]], Cos[DH[[i, 2]]] Sin[DH[[i, 4]]], Cos[DH[[i, 4]]],Cos[DH[[i, 4]]] DH[[i, 1]]}, {0, 0, 0, 1}}; 
Print["A = ", MatrixForm[A]];]

Answer 1

Here are two ways to do what you want. Which one you should choose depends on how you want to refer to the matrices produced in further calculations. If you use the 1st way, you would refer to matrices as indexed variables, A[...]. If you use the 2nd way, you would refer to them as list items, A[[...]]

DH = {{0, T1, 0, 0}, {0, T2, L1, Pi/2}, {0, T3, L2, 0}, {0, 0, L3, 0}};

• Indexed variables

Clear[A]
Do[
  A[i] = 
    {{Cos[DH[[i, 2]]], -Sin[DH[[i, 2]]], 0, DH[[i, 3]]}, 
     {Sin[DH[[i, 2]]] Cos[DH[[i, 4]]], Cos[DH[[i, 2]]] Cos[DH[[i, 4]]], 
      Sin[DH[[i, 4]]], -Sin[DH[[i, 4]]] DH[[i, 1]]}, 
     {Sin[DH[[i, 2]]] Sin[DH[[i, 4]]], Cos[DH[[i, 2]]] Sin[DH[[i, 4]]], 
      Cos[DH[[i, 4]]], Cos[DH[[i, 4]]] DH[[i, 1]]}, 
     {0, 0, 0, 1}};
  {i, Length[DH]}]
Column[Table[MatrixForm[A[i]], {i, Length[DH]}]]

• List of matrices

Clear[A]
A =
  Table[
    {{Cos[DH[[i, 2]]], -Sin[DH[[i, 2]]], 0, DH[[i, 3]]}, 
     {Sin[DH[[i, 2]]] Cos[DH[[i, 4]]], Cos[DH[[i, 2]]] Cos[DH[[i, 4]]], 
      Sin[DH[[i, 4]]], -Sin[DH[[i, 4]]] DH[[i, 1]]}, 
     {Sin[DH[[i, 2]]] Sin[DH[[i, 4]]], Cos[DH[[i, 2]]] Sin[DH[[i, 4]]], 
      Cos[DH[[i, 4]]], Cos[DH[[i, 4]]] DH[[i, 1]]},
     {0, 0, 0, 1}},
    {i, Length[DH]}];
Column[Table[MatrixForm[A[[i]]], {i, Length[A]}]]