Suppress arguments in output for pretty print

Question

I would like to define a rule that suppress any arguments of a function for visibility. I tried:

rule = f_[x__] -> f

While this works well with individual terms (including derivatives of expressions), products of functions don't work, such as

f[x] R[r] /. rule

which outputs "Times" for some reason?

Good question. While this may be seen as unfortunate, the answer to that question would be just "f", since g(x) is an argument. — Patrick.B, Nov 10 '19 at 21:12
I think I have a good answer to this question, so it would be nice to reopen. — Carl Woll, Nov 29 '19 at 05:09

Alexey Popkov · Accepted Answer · 2019-11-08T11:57:13.080

5

It's because Head[f[x] R[r]] is Times. You should rewrite your rule as

rule = f_[x__] /; ! MatchQ[f, Times] :> f

Now

f[x] R[r] /. rule

f R

I would like to define a rule that suppress any arguments of a function for visibility.

I think my shortInputForm function can be of interest for you. It doesn't completely suppress arguments but rather shortens long lists of numbers for readability.

edited Nov 08 '19 at 11:57

answered Nov 08 '19 at 11:51

Alexey Popkov

61,809
7
149
368

Carl Woll · Answer 2 · 2019-11-29T16:59:33.137

3

I think you can create a wrapper that modifies the box generation code so that it never generates brackets:

MakeBoxes[SuppressBracketArguments[expr_], StandardForm] ^:= ReplaceAll[
    MakeBoxes[expr,StandardForm],
    RowBox[{h_, "[",___,"]"}]->h
]

A couple examples:

f[g[x]] //SuppressBracketArguments
f[x] g[y] //SuppressBracketArguments

f

f g

edited Nov 29 '19 at 16:59

answered Nov 29 '19 at 16:18

Carl Woll

130,679
6
243
355

Suppress arguments in output for pretty print

2 Answers2