GeoBubbleChart Colors

Question

I'm struggling to find a way to change the default background color of a state, say the Netherlands, when using GeoBubbleChart.

When using GeoGraphics this is pretty easy. For example,

GeoGraphics[{
  EdgeForm[Black],
  FaceForm[Black],
  Polygon[GeoVariant[Entity["Country", "Belgium"], "PrincipalArea"]],
  Polygon[
   GeoVariant[Entity["Country", "Netherlands"], "PrincipalArea"]],
  Polygon[
   GeoVariant[Entity["Country", "Luxembourg"], "PrincipalArea"]]},
 GeoScaleBar -> "Metric",
 ImageSize -> Full,
 GeoBackground -> None,
 GeoRange -> {{49, 53.6}, {2, 7.5}}
 ]

However, how to obtain the same result with GeoBubbleChart?

rcollyer · Accepted Answer · 2020-03-23T14:52:40.247

7

Carl's answer is most likely what you are looking for as it limits what is in the background. But, if you are interested in changing how the background countries look, I would suggest using one of the variants of GeoStyling["CountryBorders"]. For example,

d = {Entity["Country", "Belgium"] -> Quantity[11429336, "People"], 
   Entity["Country", "Netherlands"] -> Quantity[17035938, "People"], 
   Entity["Country", "Luxembourg"] -> Quantity[583455, "People"]};

GeoBubbleChart[d,
 GeoBackground -> GeoStyling[
   {"CountryBorders", "Land" -> Gray, "Ocean" -> White, "Border" -> Black}],
 GeoRange -> GeoGroup[d[[All, 1]]]
]

The additional options also apply to "Coastlines", too.

edited Mar 23 '20 at 14:52

answered Mar 23 '20 at 14:16

rcollyer

33,976
7
92
191

Beat me to it! :) GeoStyling[] is a surprisingly flexible thing. – J. M.'s missing motivation Mar 23 '20 at 14:22
@J.M. the only complication is Dated which isn't working correctly (at this point) with the added options. But, yes, GeoStyling is a very, very nice thing. – rcollyer Mar 23 '20 at 14:23

score 6 · Answer 2 · answered Mar 23 '20 at 13:37

6

The easiest way is to use Show to combine the two:

d = {Entity["Country", "Belgium"] -> Quantity[11429336, "People"], 
   Entity["Country", "Netherlands"] -> Quantity[17035938, "People"], 
   Entity["Country", "Luxembourg"] -> Quantity[583455, "People"]};

Show[
 GeoGraphics[{EdgeForm[Black], FaceForm[Black], 
   Polygon[GeoVariant[Entity["Country", "Belgium"], "PrincipalArea"]],
    Polygon[
    GeoVariant[Entity["Country", "Netherlands"], "PrincipalArea"]], 
   Polygon[GeoVariant[Entity["Country", "Luxembourg"], 
     "PrincipalArea"]]}, GeoScaleBar -> "Metric"],
 GeoBubbleChart[d, GeoBackground -> None, 
  GeoRange -> {{49, 53.6}, {2, 7.5}}]
 ]

answered Mar 23 '20 at 13:37

Carl Lange

13,065
1
36
70

Annoyingly, this doesn't work in older versions of Mathematica. – J. M.'s missing motivation Mar 23 '20 at 14:22
@J.M. define "older". What versions? – rcollyer Mar 23 '20 at 14:24
@rcollyer, this seems to be broken in 11.2; at least it seems to be okay in 12 and 12.1. – J. M.'s missing motivation Mar 23 '20 at 14:25
@J.M. makes sense. I think Show support was added in 11.3. – rcollyer Mar 23 '20 at 14:25

kglr · Answer 3 · 2020-03-23T16:07:14.377

countries = Entity["Country", #] & /@ {"Netherlands", "Belgium", "Luxembourg"};
populations = EntityValue[countries, "Population"];

We can also use GeoRegionValuePlot to style individual country polygons

grvp = GeoRegionValuePlot[Thread[countries -> Range[Length@countries]], 
   GeoRange -> {{49, 53.6}, {2, 7.5}}, 
   ColorFunction -> (Opacity[.5, ColorData[97][#]] &), 
   ColorFunctionScaling -> False, PlotLegends -> None];

and Show grvp with GeoBubbleChart using the option GeoBackground -> None:

Show[grvp, 
 GeoBubbleChart[Thread[countries -> populations], 
  ChartBaseStyle -> Opacity[1], ColorFunction -> "Rainbow", 
  GeoRange -> {{49, 53.6}, {2, 7.5}}, GeoBackground -> None], 
 ImageSize -> Medium]

Alternatively, we can use Image @ grvp with the option GeoBackground:

GeoBubbleChart[Thread[countries -> populations], 
 ChartBaseStyle -> Opacity[1], ColorFunction -> "Rainbow", 
 GeoRange -> {{49, 53.6}, {2, 7.5}}, 
 GeoBackground -> {"Image", Image @ grvp}]

GeoBubbleChart Colors

3 Answers3