How to understand that integrals with DiracDelta?

Question

Mathematica up to version 12.1 performs

Integrate[DiracDelta[x]*Exp[-x], {x, 0, Infinity}]
(*1 - HeavisideTheta[0]*)
Integrate[DiracDelta'[x]*Exp[-x], {x, 0, Infinity}]
 (*1 - HeavisideTheta[0]*)

However, the obtained results are indeterminate and are not real numbers. How to understand it? Both Encyclopedia of Mathematics and W.Rudin. Functional analysis say nothing about such "integrals".

PS. Here is a related question in this forum.

Answer 1

Let's start by observing that the Exp[-x] factor can be ignored since DiracDelta[x] is zero except at the origin, and at the origin Exp[-x] == Exp[0] == 1. So the expression in question reduces to DiracDelta[x].

Consider the indefinite integral of DiracDelta[x]:

Integrate[DiracDelta[x], x]
(* HeavisideTheta[x] *)

HeavisideTheta[x] is zero to the left of the origin and has the value one to the right as per the definition of Dirac delta. But at the origin it is indeterminate, just as the Dirac delta itself is indeterminate at that point.

Since the lower limit of integration shown in the question is zero, we will get an indeterminate result when we compute the definite integral:

HeavisideTheta[Infinity] - HeavisideTheta[0]
(* 1 - HeavisideTheta[0] *)

To avoid this, we must ensure that neither limit of integration is on the origin -- usually on opposite sides. It is most conventional to use the entire real number line:

Integrate[DiracDelta[x], {x, -Infinity, Infinity}]
(* 1 *)

... but any finite limits will demonstrate the defined effect of integrating the Dirac delta:

Integrate[DiracDelta[x], {x, -1, 1}]
(* 1 *)

Laplace Transform

In the particular case of the Laplace transform, Mathematica offers LaplaceTransform which can evade this difficulty . In the Details and Options section of that documentation, we find:

The lower limit of the integral is effectively taken to be 0₋, so that the Laplace transform of the Dirac delta function is equal to 1.

By taking the lower limit to approach zero from the left, the indeterminancy at the origin is avoided:

LaplaceTransform[DiracDelta[x], x, 1]
(* 1 *)

We can achieve the same effect using Integrate if we explicitly specify that the lower limit of integration must approach zero from the left:

Limit[Integrate[DiracDelta[x]*Exp[-x], {x, z, Infinity}], z -> 0, Direction -> 1]
(* 1 *)

Answer 2

The answer to the OP puzzle might be in the manual page for HeavisideTheta.

HeavisideTheta[x] represents the Heaviside theta function θ(x), equal to 0 for x < 0 and 1 for x > 0.

There is no set value for θ(0) … and there should not be (unless you commit to certain convention). In the Wikipedia page, the plot specifically mentions "using the half-maximum convention" but that is a convention that MMA is not using. Hence, 1 - HeavisideTheta[0] should be read as 1 minus some value I don't care or know. That is a perfectly valid answer from MMA.

---

There are many cases where MMA tells you "I don't care or I don't know". In the answer to

Solve[Tan[x] == 1]
(*x -> ConditionalExpression[π/4 + π C[1], C[1] \[Element] Integers]*)

MMA tells you "π/4 plus π times an integer that I don't care or know. It is up to you to decide what integer fits your needs."

In Heaviside[0], MMA implies that it is up to you to pick the convention that suits your needs.