How to remove the sign before the element

Question

I want to get rid of the sign in front of the element, but the symbol variables are involved, so I can't use the Abs function to get rid of the sign.

I want this list {-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3]} to be processed to {1, 2, 3, 4, x, x, Fx[3], Fx[3]}.

In addition, What should I do when the list contains a ± sign? For example, when the list is {-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3], -Fx[-3], ±Fy[-2] ,±Fy[±x]}.

@Mr.Wizard What should I do when the list contains a ± sign? I've updated the question. — , Apr 02 '20 at 22:40
user216, please see my updated answer. @user1066 That's nice! Why not post a formal Answer? — Mr.Wizard, Apr 03 '20 at 11:25

score 16 · Accepted Answer · answered Apr 02 '20 at 07:26

16

I am sure there are many ways to do this. One possible way could be

ClearAll[x,Fx];
expr = {-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3]};
Times[Internal`SyntacticNegativeQ /@ expr /. {True -> (-1), False -> 1}, expr]

gives

 {1, 2, 3, 4, x, x, Fx[3], Fx[3]}

answered Apr 02 '20 at 07:26

Nasser

143,286
11
154
359

score 7 · Answer 2 · answered Apr 02 '20 at 08:19

7

What about

expr   /. y_ /; y < 0 -> -y 
(*{1, 2, 3, 4, x, x, Fx[3], Fx[3]}*)

answered Apr 02 '20 at 08:19

Ulrich Neumann

53,729
2
23
55

Clever, but beware something like -Fx[-1] – Mr.Wizard Apr 02 '20 at 10:30
@Mr.Wizard obviously to simple! Other problems arise if you consider expressions like -g[x]+f[-x] – Ulrich Neumann Apr 02 '20 at 10:39
1

It fits the given example however, and I like terse, so you already have my up-vote. :-) – Mr.Wizard Apr 02 '20 at 10:39
Me too, thanks. – Ulrich Neumann Apr 02 '20 at 10:40

Mr.Wizard · Answer 3 · 2020-04-03T11:24:00.337

Not as terse as Ulrich's replacement, but perhaps more robust:

list = {-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3], -Fx[-1], +Fx[-1]};

Replace[a : -_ | _?Negative :> -a] /@ list

{1, 2, 3, 4, x, x, Fx[3], Fx[3], Fx[-1], Fx[-1]}

Updated for your latest example:

list2 = {-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3], -Fx[-1], +Fx[-1], ±Fy[-2], ±Fy[±x]};

Replace[{a : -_ | _?Negative :> -a, ±a_ :> a}] /@ list2

{1, 2, 3, 4, x, x, Fx[3], Fx[3], Fx[-1], Fx[-1], Fy[-2], Fy[±x]}

kglr · Answer 4 · 2020-04-03T12:10:54.330

6

ClearAll[removeSigns]

removeSigns = # Sign[#] /. Sign -> (1 &) &;

removeSigns @ {-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3]}

{1, 2, 3, 4, x, x, Fx[3], Fx[3]}

Also

ClearAll[removeSigns2, removeSigns3, removeSigns4, removeSigns5]

removeSigns2 = Abs[#] /. Abs -> (# &) &

removeSigns3 = ReplaceAll[Abs -> Identity] @* Abs

removeSigns4 = Map[Replace[Abs[x_] :> x]]@*Abs (*thanks: Mr.Wizard *)

removeSigns5 = Function[{x}, If[Internal`SyntacticNegativeQ[x], -x, x], Listable];

edited Apr 03 '20 at 12:10

answered Apr 02 '20 at 08:08

kglr

394,356
18
477
896

1

Consider also: Replace[Abs[x_] :> x] /@ Abs[list] -- this would not strip inner appearances of Abs. – Mr.Wizard Apr 02 '20 at 10:58

score 5 · Answer 5 · answered Apr 03 '20 at 11:46

5

Sqrt[lst lst]//PowerExpand

{1, 2, 3, 4, x, x, Fx[3], Fx[3]}

(Originally posted as a comment)

answered Apr 03 '20 at 11:46

user1066

17,923
3
31
49

score 2 · Answer 6 · answered Feb 15 '24 at 00:28

Position-based solutions

1.

list = {-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3]};
p = Position[list, _Times | _?Negative, 1];

Using ReplaceAt (new in 13.1)

ReplaceAt[x_ :> -x, p] @ list

{1, 2, 3, 4, x, x, Fx[3], Fx[3]}

2.

list = {-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3], -Fx[-1], +Fx[-1], ±Fy[-2], ±Fy[±x]};
p = Position[list, _Times | _?Negative | _PlusMinus, 1];
ReplaceAt[{x_PlusMinus :> x[[1]], x_ :> -x}, p] @ list

{1, 2, 3, 4, x, x, Fx[3], Fx[3], Fx[-1], Fx[-1], Fy[-2], Fy[±x]}

score 2 · Answer 7 · answered Feb 15 '24 at 03:15

list1 = {-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3], -Fx[-1], +Fx[-1]};

list2 = {-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3], -Fx[-1], +Fx[-1], ±Fy[-2], ±Fy[±x]};

Using Abs, FactorList and ReplaceAll:

f = Function[a, If[NumericQ@a, Abs@a, 
    FactorList[a /. b_ /; Head[b] === PlusMinus :> b[[1]]][[2, 1]]], Listable];
f@list1
f@list2

Results:

{1, 2, 3, 4, x, x, Fx[3], Fx[3], Fx[-1], Fx[-1]}

{1, 2, 3, 4, x, x, Fx[3], Fx[3], Fx[-1], Fx[-1], Fy[-2], Fy[±x]}

score 1 · Answer 8 · answered Feb 15 '24 at 06:20

Just for fun:

func = (ToBoxes@# /. RowBox[{"-" | "±", a_}] :> a // ToExpression) &;
func@{-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3]}
(* {1, 2, 3, 4, x, x, Fx[3], Fx[3]} *)
func@{-1, -2, +3, 4, -x, +x, -Fx[3], +Fx[3], -Fx[-3], ±Fy[-2], ±Fy[±x]}
(* {1, 2, 3, 4, x, x, Fx[3], Fx[3], Fx[-3], Fy[-2], Fy[±x]} *)

How to remove the sign before the element

8 Answers8