21

When I use RegionPlot to plot the region between two functions, I get strange gaps in the resulting figure. Is there a way to prevent this from happening?

For example, 

RegionPlot[x^2 < y && y < x^4, {x, -3, 3}, {y, 0, 3}]

produces the following strange result:

enter image description here

J. M.'s missing motivation
  • 124,525
  • 11
  • 401
  • 574
orome
  • 12,819
  • 3
  • 52
  • 100

2 Answers2

23

Just increase the number of PlotPoints

RegionPlot[x^2 < y && y < x^4, {x, -3, 3}, {y, 0, 3}, 
  PlotPoints -> 100]

enter image description here

Verbeia
  • 34,233
  • 9
  • 109
  • 224
  • 9
    As a note, some functions require a lot more than 100 points, I've needed upwards of 500 in some cases. Also, x and y can have different number of points via PlotPoints -> {100, 150}. – rcollyer Jan 17 '12 at 22:58
  • 3
    This same principle also applies to other Plot functions. Sometimes Mathematica gets unlucky with sampling the function and you get discontinuities or odd behavior. In almost every case, either increasing PlotPoints or MaxRecursion will help. – Mike Bailey Jan 17 '12 at 23:24
16

Or, the MaxRecursion:

RegionPlot[x^2 < y && y < x^4, {x, -3, 3}, {y, 0, 3},
  MaxRecursion -> 8]

The plot commands generally use a adaptive procedure that is applied recursively. MaxRecursion controls how many times this recursion can be applied. PlotPoints by contrast, simply indicates how many points should be used in the initial grid. It might be simplest to illustrate with the most basic Plot command:

Manipulate[
  Plot[Sin[x^2], {x, 0, 3},
    Mesh -> All, PlotRange -> 1.1,
    MaxRecursion -> mr, PlotPoints -> pp],
  {mr, 0, 8, 1}, {pp, 4, 100, 1}]

Mathematica graphics

This is a visualization of the sampling mesh for your example function:

RegionPlot[{x^2 < y && y < x^4, Not[x^2 < y && y < x^4]}, 
    {x, -3, 3}, {y, 0, 3}, Mesh -> All, MaxRecursion -> 4]

Mathematica graphics

Szabolcs
  • 234,956
  • 30
  • 623
  • 1,263
Mark McClure
  • 32,469
  • 3
  • 103
  • 161
  • What are the tradeoffs between MaxRecursion and PlotPoints? – orome Jan 17 '12 at 22:44
  • 2
    MaxRecursion is adaptive and should be the preferable solution (faster for a given required plot accuracy). Compare: ImageDifference[RegionPlot[x^2<y&&y<x^4,{x,-3,3},{y,0,3},MaxRecursion->8],RegionPlot[x^2<y&&y<x^4,{x,-3,3},{y,0,3},PlotPoints->100]] – Andrew Moylan Jan 17 '12 at 22:53
  • @ras See the edit. – Mark McClure Jan 17 '12 at 23:00
  • Mark, you have a typo in the first line -> "MaxRecursion". – Andrew Moylan Jan 17 '12 at 23:05
  • 8
    @raxacoricofallapatorius PlotPoints is good for making sure features show up; MaxRecursion is better for "polishing" off the edges. (MaxRecursion generally can't improve something that isn't there to start with.) – Brett Champion Jan 18 '12 at 05:01
  • 3
    @AndrewMoylan Isn't it the case the to avoid holes or missing parts, one generally needs to increase PlotPoints, while MaxRecursion is only for increasing the accuracy of already found regions? While in this example it works well, I'm often a bit wary of MaxRecursion because of its exponential nature (increasing it by one may increase the plotting time significantly) – Szabolcs Jan 18 '12 at 15:37
  • Yes that's a good point Szabolcs. Brett's comment has the best general advice. – Andrew Moylan Jan 18 '12 at 18:57
  • I edited your answer slightly to include some visualizations I thought were valuable. Can you please review the changes? – Szabolcs Jan 24 '12 at 16:24