Is it possible for a Mathematica notebook to display its own metadata like last modified date and filename when opened?

Question

Abstract: when managing hundreds of notebook files without a git system (version management) it would be very convenient to automatically show its own filename and last modified date at the top when opened. Can this be done?

About the Code: Here is my very bad attempt at doing this that fails miserably.

FileDate["D:\Google Drive\projects\experiments\data\statistics.nb"]

If you have hundreds of files to keep track of, all under constant modification, then perhaps a version control system is a must. Consider the advice here: What are the recommended settings for git when using with Mathematica projects?. — MarcoB, Jun 02 '20 at 20:04
This answer to speedup and get more flexable control Notebook History might also be relevant, with some modification. — MarcoB, Jun 02 '20 at 20:07

score 7 · Accepted Answer · answered Jun 02 '20 at 20:19

Here's one approach using a docked cell:

SetOptions[EvaluationNotebook[], 
 DockedCells -> 
  Cell[BoxData[
    ToBoxes[Dynamic[
      Column[{NotebookFileName[], 
        DateString[
         Information[EvaluationNotebook[], "FileModificationTime"]]}],
       UpdateInterval -> 60]]]]]

The content updates once a minute. You could set this globally by using $FrontEnd (survives through restarting the frontend) or $FrontEndSession (cleared by restarting the frontend), but you'll want to add some logic for what to display in a new notebook that has never been saved to disk (and maybe also notebooks that live in the cloud.)

Jules Manson · Answer 2 · 2020-06-05T06:16:30.057

After digging through documentation I have found that there is a way and it's very easy. I packaged it into a nice little function for giving current user, current open file, and date modified and as a bonus I even included a function to clear memory.

Here ya go:

Clear["Global`*"]
systemInfo[] := Column[{Row[{Style["User: ", Bold], $Username}],
   Row[{Style["Filename: ", Bold], FileNameTake[NotebookFileName[]]}],
   Row[{Style["Last Modified: ", Bold], 
     DateString[FileDate[NotebookFileName[]]]}]}
  ]
clearMemory[] := {MemoryInUse[], Unprotect[In, Out], Clear[In, Out], 
   Protect[In, Out], MemoryInUse[]};
systemInfo[]
clearMemory[]

Is it possible for a Mathematica notebook to display its own metadata like last modified date and filename when opened?

2 Answers2