How can I prevent Mathematica from evaluating or "simplifying" an expression?

Question

Simple example:

k = 5;
list = {};
For[i = 1, i <= k - 2,
 AppendTo[list, 1/(1 + Cos[i Pi/k])];
 i = i + 2];
Print[list];

{1/(1+1/4 (1+Sqrt[5])),1/(1+1/4 (1-Sqrt[5]))}

I want the expression to be kept and printed as:

{1/(1 + Cos[Pi/5]), 1/(1 + Cos[3 Pi/5])}

I have tried Hold and its several versions, but nothing seems to do the trick.

Welcome to Mathematica.SE! I suggest the following:

As you receive help, try to give it too, by answering questions in your area of expertise.

Read the [faq]!

When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge.

Also, please remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign! — chris, Apr 01 '13 at 07:03

score 3 · Answer 1 · answered Mar 31 '13 at 22:42

3

k = 5;
list = {};
For[i = 1, i <= k - 2, 
  With[{i = i, k = k}, 
   AppendTo[list, HoldForm[1/(1 + Cos[(i \[Pi])/k])]]];
  i = i + 2];
Print[list];

Mathematica graphics

answered Mar 31 '13 at 22:42

Sjoerd C. de Vries

65,815
14
188
323

1

Perhaps Table[With[{i = i, k = k}, HoldForm[1/(1 + Cos[i Pi /k])]], {i, 1, k - 2, 2}] is more Mathemaica-ish – Dr. belisarius Mar 31 '13 at 23:22
@belisarius I know, but that's not what the OP wanted. – Sjoerd C. de Vries Apr 01 '13 at 08:31
Sjoerd: I know you know :). I was "talking" to the OP. Sorry for the confusion – Dr. belisarius Apr 01 '13 at 08:46

score 3 · Answer 2 · answered Apr 01 '13 at 00:06

As stated HoldForm is your friend here. Also see Defer if you intend to reuse the output.

Equivalent methods:

Table[With[{i = i, k = k}, HoldForm[1/(1 + Cos[i Pi/k])]], {i, 1, k - 2, 2}]

Table[{i, k} /. {i_, k_} :> HoldForm[1/(1 + Cos[i Pi/k])], {i, 1, k - 2, 2}]

Table[HoldForm[1/(1 + Cos[# Pi/#2])] &[i, k], {i, 1, k - 2, 2}]

Mathematica graphics

How can I prevent Mathematica from evaluating or "simplifying" an expression?

2 Answers2

Linked