How to plot a 3D surface with a simple black and white style?

Question

Mathematica has great plotting capabilities. However, sometimes what is needed is a very basic black and white plot without textures, lighting, glow and other complex features. So, here is my question: what kind of Plot3D options will allow me to get something similar to

score 25 · Accepted Answer · answered Apr 03 '13 at 04:52

25

I would say you go for the Lighting option:

Plot3D[Exp[-(x^2 + y^2)], {x, -2, 2}, {y, -2, 2}, 
 Lighting -> {{"Ambient", White}}, PlotRange -> All, Mesh -> {20}]

Mathematica graphics

answered Apr 03 '13 at 04:52

halirutan

112,764
7
263
474

1

In fact, Lighting -> {White} is enough. – xzczd Apr 03 '13 at 04:54
2

yes, but I wanted to mention explicitly that it's the ambient light which prevents shading. – halirutan Apr 03 '13 at 05:01
5

In V10 PlotStyle->White is necessary to deal with an orange plot. One can also add PlotPoints->22, MaxRecursion->0 to obtain really old-school plot :) – ybeltukov Sep 07 '14 at 13:11

Vitaliy Kaurov · Answer 2 · 2013-04-03T15:51:47.387

20

Just a few alternatives. (from @Mr.Wizard) If one prefers to have it simple but to keep shading, then

Plot3D[Exp[-(x^2 + y^2)], {x, -2, 2}, {y, -2, 2}, 
 Lighting -> "Neutral", PlotRange -> All, Mesh -> {20}]

enter image description here

Some may want to have transparent mesh

Plot3D[Exp[-(x^2 + y^2)], {x, -2, 2}, {y, -2, 2}, PlotRange -> All, 
 Mesh -> {20}, PlotStyle -> Opacity[0], MeshStyle -> Opacity[.5]]

or from @J.M.

Plot3D[Exp[-(x^2 + y^2)], {x, -2, 2}, {y, -2, 2}, 
 PlotStyle -> FaceForm[None], PlotRange -> All, Mesh -> {20}]

enter image description here

edited Apr 03 '13 at 15:51

answered Apr 03 '13 at 05:48

Vitaliy Kaurov

73,078
9
204
355

Do you have any thoughts about ColorFunction -> (White &) versus Lighting -> "Neutral"? I typically use the latter. – Mr.Wizard Apr 03 '13 at 06:22
For the second: PlotStyle -> FaceForm[None] works nicely, too. – J. M.'s missing motivation Apr 03 '13 at 07:51
@Mr.Wizard Lighting -> "Neutral" is more efficient I think - I edited it into my code. Thx ;) – Vitaliy Kaurov Apr 03 '13 at 15:52
@J.M. Yes, nice observation ;) – Vitaliy Kaurov Apr 03 '13 at 15:53
@Mr. Wizard, through close reading of the docs for Plot3D[], it would seem that ColorFunction -> (White &) is entirely equivalent to the default ColorFunction -> Automatic, so one does not really need to tweak ColorFunction for a plain Jane plot... – J. M.'s missing motivation Apr 03 '13 at 16:02

J. M.'s missing motivation · Answer 3 · 2013-04-12T10:31:29.350

17

If one wants a simple wireframe mesh, as in Vitaliy's answer, here's yet another method:

DeleteCases[Plot3D[Exp[-(x^2 + y^2)], {x, -2, 2}, {y, -2, 2}, Mesh -> {20}], _Polygon, ∞]

wireframe plot

As it turns out, however, there is an even simpler way to generate a nice wiremesh:

Plot3D[Exp[-(x^2 + y^2)], {x, -2, 2}, {y, -2, 2}, Mesh -> {20}, PlotStyle -> None]

edited Apr 12 '13 at 10:31

answered Apr 11 '13 at 12:12

J. M.'s missing motivation

124,525
11
401
574

2

There's a certain beauty to this approach. "Polygons, begone!" :-) – Mr.Wizard Apr 11 '13 at 12:58
That's more or less how I read the code, too. :) – J. M.'s missing motivation Apr 11 '13 at 13:20

score 7 · Answer 4 · edited Mar 06 '18 at 16:03

7

Just to mention, for me the accepted answer does not bring the desired result with Mathematica 10. Instead, what I get when running

Plot3D[
  Cos[2 Norm[{x, y}]], {x, 0, 10}, {y, 0, 10},  
  Lighting -> {"Ambient", White},  
  PlotRange -> All, Mesh -> {20}, BoxRatios -> {1, 1, 0.1},  
  Boxed -> False, Axes -> False]

is this:

However, a color function did the difference for me:

Plot3D[
  Cos[2 Norm[{x, y}]], {x, 0, 10}, {y, 0, 10},  
  Lighting -> {"Ambient", White}, 
  ColorFunction -> Function[{x, y, z}, White],  
  PlotRange -> All, Mesh -> {20}, BoxRatios -> {1, 1, 0.1}, 
  Boxed -> False, Axes -> False]

edited Mar 06 '18 at 16:03

m_goldberg

107,779
16
103
257

answered Mar 06 '18 at 12:45

Nils

71
1
1

2

ColorFunction -> (White &) also works. – bbgodfrey Mar 06 '18 at 13:51
2

"Just to mention, for me the accepted answer does not bring the desired result with Mathematica 10. " - The default light sources changed in version 10(?), while the answers that came before you were done in version 8. – J. M.'s missing motivation Mar 06 '18 at 14:46
1

You should be able to get this with PlotStyle->White too. Might even be faster. – b3m2a1 Mar 06 '18 at 17:55

How to plot a 3D surface with a simple black and white style?

4 Answers4

Linked

Related