How to capture Print output

Question

How can I capture output from Print from a function which does not leave the printed object as its final output, (and which I do not wish to edit)? E.g.

Module[{},
 Print[Plot[Sin[x], {x, 0, 2 Pi}]];
 a = 123]

I would like to use something like a temporary setting for $PrePrint or $Post, rather than use cell selection (SelectionMove, NotebookRead).

The aim is somehow to intercept the Print output -- the plot object -- and set it to a variable, (without altering the module).

This attempt did not work:-

enter image description here

I probably don't understand the problem but doesn't Print[Sow@Plot[Sin[x], {x, 0, 2 Pi}]] and // Reap at the end captures Print output? — BoLe, Apr 03 '13 at 11:00
I just want to pick up the plot object. The problem is the module should not be edited, otherwise it would be simple to set a variable inside the Print command. — Chris Degnen, Apr 03 '13 at 12:11
So you want something like $PrePrint or $Post which would also capture the output of Plot[Sin[x],{x,-5,5}];? — acl, Apr 03 '13 at 12:32
@acl - Yes, as I have done below using $Output. But setting a variable with $PrePrint could be neater. — Chris Degnen, Apr 03 '13 at 12:56
@J.M. - no, I can't see how CellPrint could be used. But the idea is not to alter the module. — Chris Degnen, Apr 03 '13 at 15:05
If you need to collect the printed output and it's lready generated, you may try my answer here http://mathematica.stackexchange.com/a/38220/193 — Dr. belisarius, Dec 03 '13 at 22:48

Chris Degnen · Answer 1 · 2013-04-03T12:58:14.680

9

I have found one solution, using a temporary file:-

streams = AppendTo[$Output, OpenWrite[]];

Module[{},
  Print[Plot[Sin[x], {x, 0, 2 Pi}]];
  a = 123];

Close@Last@streams;
$Output = Most@streams;
printoutput = ReadList@First@Last@streams

enter image description here

edited Apr 03 '13 at 12:58

answered Apr 03 '13 at 12:52

Chris Degnen

30,927
2
54
108

This is great! Anyway to modify it so that the printed text is not outputted at all, but still captured to printoutput? – Kvothe Jun 16 '21 at 15:50
@Kvothe Yes, use Block as per Szabolcs' answer. (Writes to list.) – Chris Degnen Jun 16 '21 at 16:48
Thanks. I wrongly assumed that the Block method would not work for my case since the printed output is printed in python during ExternalEvaluate. Upon testing it does actually work so apparently these statements still get printed in Mathematica by internally using Print. – Kvothe Jun 17 '21 at 07:56

score 6 · Accepted Answer · edited May 23 '17 at 12:35

You can temporarily redefine Print, like so:

fun[] := Module[{}, Print[Plot[Sin[x], {x, 0, 2 Pi}]];
  a = 123]

list = {};
Block[{Print = AppendTo[list, {##}] &}, fun[]]

Now list contains everything that was printed. (Of course in a practical application you'd probably want to do something smarter than an inefficient periodic AppendTo)

If you still want to print the expressions while simultaneously saving them, use the Villegas-Gayley trick to redefine Print.

How to capture Print output

2 Answers2

Linked