How to solve this equation with rank relation of matrix

Question

It has been known that matrix A is equivalent to matrix B, and I want to find the possible value of parameter a (the answer is a = 2). This question is slightly different from that of this post.

A = {{1, 2, a}, {1, 3, 0}, {2, 7, -a}}; 
B = {{1, a, 2}, {0, 1, 1}, {-1, 1, 1}}; 
Solve[MatrixRank[A] == MatrixRank[B], a]

The above code can not output the correct results, I need your help.

Besides, I have another question. I find that RowReduce-function can't make the matrix with parameters into row simplest type:

RowReduce[{{1, a, 2}, {0, 1, 1}, {-1, 1, 1}}]

The row simplest form of matrix $\left(\begin{array}{ccc} 1 & a & 2 \\ 0 & 1 & 1 \\ -1 & 1 & 1 \end{array}\right)$ should be $\left(\begin{array}{ccc} 1 & -1 & -1 \\ 0 & 1 & 1 \\ 0 & a-2 & 0 \end{array}\right)$ instead of $\left(\begin{array}{lll} 1 & 0 & 0 \\ 0 & 1 & 0 \\ 0 & 0 & 1 \end{array}\right)$. I wonder if this error is a bug in the RowReduce function.

In addition, sometimes it is necessary to deal with the following non square matrix equation:

A = {{1, -1, -1}, {2, a, 1}, {-1, 1, a}}; B = {{2, 2}, {1, 
   a}, {-a - 1, -2}}; 
Solve[MatrixRank[A] == 
    MatrixRank[Join[A, B, 2]], a, Reals]

To address the last question: This is not a bug in RowReduce (nor is it an error). — Daniel Lichtblau, Aug 05 '20 at 14:50
@DanielLichtblau If it's not a bug I would argue, though, that the documentation does a pretty bad job at explaining this limitation. Would it be feasible for RowReduce to have a GenerateConditions option to at least be able to keep track of the conditions that that make the reduced form valid? — Sjoerd Smit, Aug 20 '20 at 08:42
@SjoerdSmit (1) I don't think such an option is likely to be added but in theory it is feasible. One way to obtain such information is to augment the matrix with an identity matrix on the right (as though finding a matrix inverse as taught in linear algebra), then row reduce, then take denominators in the augmented section as nonvanishing conditions. — Daniel Lichtblau, Aug 20 '20 at 14:20
@SjoerdSmit (2) See also this old response to a similar question, for adapting the ZeroTest option. — Daniel Lichtblau, Aug 20 '20 at 14:22

Sjoerd Smit · Accepted Answer · 2020-08-11T06:50:10.933

5

It looks like RowReduce and MatrixRank implicitly assume that a does not have a particular value that reduces the rank of the matrix. They can detect that matrix A is degenerate for any value of a, but not that B is degenerate for a == 2.

I think you might be able to get around this with SingularValueList, which seems to handle the problem better:

Assuming[a \[Element] Reals,
  Simplify[Reduce[Simplify[#] == 0] & /@ SingularValueList[A]]
]
Assuming[a \[Element] Reals,
  Simplify[Reduce[Simplify[#] == 0] & /@ SingularValueList[B]]
]

{False, False}

{a == 2, False, False}

From this you can see that A always has rank 2 while B has rank 3 any value of a other than 2.

Edit

Here's a quick attempt to do what you asked directly:

symbolicMatrixRank[mat_, assumptions_] := Assuming[assumptions,
   Simplify @ Total @ Simplify[
     Boole[!Reduce[Simplify[#] == 0]] & /@ SingularValueList[mat]
   ]
];
Solve[symbolicMatrixRank[A, a ∈ Reals] == symbolicMatrixRank[B, a ∈ Reals]]

{{a -> 2}}

or similarly:

symbolicMatrixRank[mat_, assumptions_] := Assuming[assumptions,
  Simplify @ Total @ Map[
    Boole @ Simplify @ Reduce[ConditionalExpression[#, $Assumptions] != 0]&,
    SingularValueList[mat]
  ]
];

As noted in a comment, Solve doesn't not always seem to deal with these sort of piecewise equations too well. Resolve is more adapt at solving them.

edited Aug 11 '20 at 06:50

answered Aug 04 '20 at 11:19

Sjoerd Smit

23,370
46
75

Your answer is great, but how to deal with the following non square matrix equation:A = {{1, -1, -1}, {2, a, 1}, {-1, 1, a}}; B = {{2, 2}, {1, a}, {-a - 1, -2}}; Solve[symbolicMatrixRank[A, Element[a, Reals]] == symbolicMatrixRank[Join[A, B, 2], Element[a, Reals]]]. – A little mouse on the pampas Aug 09 '20 at 07:46
1

@Montevideo For some reason Solve doesn't handle this very well. Try Reduce instead. It should give you 2 + a != 0. – Sjoerd Smit Aug 10 '20 at 19:18
Thank you very much for your help. – A little mouse on the pampas Aug 10 '20 at 22:48
Sorry to disturb you again. Why can't the following code return the correct result ({a -> 2, b -> -3}):mat = {{1, 1, 1, 1}, {4, 3, 5, -1}, {a, 1, 3, b}}; augmat = {{1, 1, 1, 1, -1}, {4, 3, 5, -1, -1}, {a, 1, 3, b, 1}}; symbolicMatrixRank[mat_, assumptions_] := Assuming[assumptions, Simplify[Total[ Simplify[(Boole[ ! Reduce[Simplify[#1] == 0]] & ) /@ SingularValueList[mat]]]]]; Reduce[symbolicMatrixRank[mat, Element[a, Reals] && Element[b, Reals]] == symbolicMatrixRank[augmat, Element[a, Reals] && Element[b, Reals]] == 2]. – A little mouse on the pampas Aug 16 '20 at 07:25
1

@Montevideo Try the second form of symbolicMatrixRank I put in my answer. That one works here. Depending on the returned value of SingularValueList, you may need to wrangle a little with how you call Reduce and Simplify. I won't claim that these functions work for every imaginable matrix. – Sjoerd Smit Aug 16 '20 at 19:26
Thank you very much. I haven't used the second method. I thought they were exactly the same. – A little mouse on the pampas Aug 16 '20 at 22:45
I'm sorry to trouble you again. No matter what kind of definition of function symbolicMatrixRank is used in the following code, the desired result (a + b + c = =0) cannot be obtained: Reduce[symbolicMatrixRank[{{a, 2*b}, {b, 2*c}, {c, 2*a}}, Element[a, Reals] && Element[b, Reals] && Element[c, Reals]] == symbolicMatrixRank[{{a, 2*b, -3*c}, {b, 2*c, -3*a}, {c, 2*a, -3*b}}, Element[a, Reals] && Element[b, Reals] && Element[c, Reals]] == 2]. – A little mouse on the pampas Aug 20 '20 at 08:15
1

@Montevideo Please ask a new question. The comments aren't the right place for this. – Sjoerd Smit Aug 20 '20 at 08:25
If you have time, I hope you can answer my new question. Thank you very much. – A little mouse on the pampas Aug 20 '20 at 11:20
1

@Montevideo I'm a bit busy atm, but I'll have a look when I have time. – Sjoerd Smit Aug 20 '20 at 12:57

yode · Answer 2 · 2022-07-27T12:27:47.507

I have made a MatrixRankSym feature with symbolic computation here. And we can use it directly:

For your first equation:

A = {{1, 2, a}, {1, 3, 0}, {2, 7, -a}};
B = {{1, a, 2}, {0, 1, 1}, {-1, 1, 1}};
Reduce[MatrixRankSym[A] == MatrixRankSym[B], a]

a == 2

For your second non square matrix equation:

A = {{1, -1, -1}, {2, a, 1}, {-1, 1, a}};
B = {{2, 2}, {1, a}, {-a - 1, -2}};
Reduce[MatrixRankSym[A] == MatrixRankSym[Join[A, B, 2]], a, Reals]

a < -2 || a > -2

How to solve this equation with rank relation of matrix

2 Answers2

Edit

Linked